Acme::CPANAuthors - We are CPAN authors

Acme-CPANAuthors documentation Contained in the Acme-CPANAuthors distribution.

Index

Code Index:

NAME

Top

Acme::CPANAuthors - We are CPAN authors

SYNOPSIS

Top

    use Acme::CPANAuthors;

    my $authors = Acme::CPANAuthors->new('Japanese');

    my $number   = $authors->count;
    my @ids      = $authors->id;
    my @distros  = $authors->distributions('ISHIGAKI');
    my $url      = $authors->avatar_url('ISHIGAKI');
    my $kwalitee = $authors->kwalitee('ISHIGAKI');
    my @info     = $authors->look_for('ishigaki');

  If you don't like this interface, just use a specific authors list.

    use Acme::CPANAuthors::Japanese;

    my %authors = Acme::CPANAuthors::Japanese->authors;

    # note that ->author is context sensitive.
    # however, you can't write this without dereference
    # as "keys" checks the type (actually, the number) of args.
    for my $name (keys %{ Acme::CPANAuthors::Japanese->authors }) {
      print Acme::CPANAuthors::Japanese->authors->{$name}, "\n";
    }

DESCRIPTION

Top

Sometimes we just want to know something to confirm we're not alone, or to see if we're doing right things, or to look for someone we can rely on. This module provides you some basic information on us.

WHY THIS MODULE?

Top

We've been holding a Kwalitee competition for Japanese CPAN Authors since 2006. Though Japanese names are rather easy to distinguish from Westerner's names (as our names have lots of vowels), it's tedious to look for Japanese authors every time we hold the contest. That's why I wrote this module and started maintaining the Japanese authors list with a script to look for candidates whose name looks like Japanese by the help of Lingua::JA::Romaji::Valid I coined.

Since then, dozens of lists are uploaded on CPAN. It may be time to start other games, like offering more useful statistics online.

ENVIRONMENTAL VARIABLE

Top

ACME_CPANAUTHORS_HOME

Since 0.14, Acme::CPANAuthors checks ACME_CPANAUTHORS_HOME environmental variable to look for a place where CPAN indices are located. If you have a local (mini) CPAN mirror, or a source directory for your CPAN clients (~/.cpan/sources etc), set the variable to point there. If not specified, the indices will be downloaded from the CPAN (to your temporary directory, or to the current directory).

METHODS

Top

new

creates an object and loads the subclasses you specified. If you don't specify any subclasses, it tries to load all the subclasses found just under the "Acme::CPANAuthors" namespace (except Acme::CPANAuthors::Not).

count

returns how many CPAN authors are registered.

id

returns all the registered ids by default. If called with an id, this returns if there's a registered author of the id.

name

returns all the registered authors' name by default. If called with an id, this returns the name of the author of the id.

distributions, latest_distributions

returns an array of Parse::CPAN::Packages::Distribution objects for the author of the id. See Parse::CPAN::Packages for details.

avatar_url

returns gravatar url of the id shown at search.cpan.org. see http://site.gravatar.com/site/implement for details.

kwalitee

returns kwalitee information for the author of the id. This information is scraped from http://kwalitee.perl.org/.

look_for

  my @authors = Acme::CPANAuthors->look_for('SOMEONE');
  foreach my $author (@authors) {
    printf "%s (%s) belongs to %s.\n",
      $author->{id}, $author->{name}, $author->{category};
  }

takes an id or a name (or a part of them, or even a regexp) and returns an array of hash references, each of which contains an id, a name, and a basename of the class where the person is registered. Note that this will load all the installed Acme::CPANAuthors:: modules but Acme::CPANAuthors::Not and modules with deeper namespaces.

SEE ALSO

Top

As of writing this, there're more than a dozen of lists on the CPAN, including:

Acme::CPANAuthors::Arabic
Acme::CPANAuthors::Austrian
Acme::CPANAuthors::Brazilian
Acme::CPANAuthors::Canadian
Acme::CPANAuthors::Chinese
Acme::CPANAuthors::Dutch
Acme::CPANAuthors::French
Acme::CPANAuthors::German
Acme::CPANAuthors::Icelandic
Acme::CPANAuthors::Indonesian
Acme::CPANAuthors::Israeli
Acme::CPANAuthors::Italian
Acme::CPANAuthors::Japanese
Acme::CPANAuthors::Korean
Acme::CPANAuthors::Norwegian
Acme::CPANAuthors::Portuguese
Acme::CPANAuthors::Russian
Acme::CPANAuthors::Taiwanese
Acme::CPANAuthors::Turkish
Acme::CPANAuthors::Ukrainian

These are not regional ones but for some local groups.

Acme::CPANAuthors::Booking
Acme::CPANAuthors::British::Companies
Acme::CPANAuthors::CodeRepos
Acme::CPANAuthors::GeekHouse
Acme::CPANAuthors::GitHub

These are lists for specific module authors.

Acme::CPANAuthors::AnyEvent
Acme::CPANAuthors::DualLife
Acme::CPANAuthors::POE
Acme::CPANAuthors::ToBeLike
Acme::CPANAuthors::Acme::CPANAuthors::Authors

And other stuff.

Acme::CPANAuthors::CPANTS::FiveOrMore
Acme::CPANAuthors::Female
Acme::CPANAuthors::Misanthrope
Acme::CPANAuthors::Not
Acme::CPANAuthors::Pumpkings
Acme::CPANAuthors::Search (now CPAN::AuthorsSearch)
Acme::CPANAuthors::You::re_using

Thank you all. And I hope more to come.

AUTHOR

Top

Kenichi Ishigaki, <ishigaki at cpan.org>

COPYRIGHT AND LICENSE

Top

Copyright (C) 2007-2010 by Kenichi Ishigaki.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

Acme-CPANAuthors documentation Contained in the Acme-CPANAuthors distribution. 
package Acme::CPANAuthors;

use strict;
use warnings;
use Carp;
use Acme::CPANAuthors::Utils qw( cpan_authors cpan_packages );

our $VERSION = '0.16';

sub new {
  my ($class, @categories) = @_;

  @categories = _list_categories() unless @categories;

  my %authors;
  foreach my $category ( @categories ) {
    %authors = ( %authors, _get_authors_of($category) );
  }
  bless \%authors, $class;
}

sub count {
  my $self = shift;

  return scalar keys %{ $self };
}

sub id {
  my ($self, $id) = @_;

  unless ( $id ) {
    return sort keys %{ $self };
  }
  else {
    return $self->{$id} ? 1 : 0;
  }
}

sub name {
  my ($self, $id) = @_;

  unless ( $id ) {
    return sort values %{ $self };
  }
  else {
    return $self->{$id};
  }
}

sub distributions {
  my ($self, $id) = @_;

  return unless $id;

  my @packages;
  foreach my $package ( cpan_packages->distributions ) {
    if ( $package->cpanid eq $id ) {
      push @packages, $package;
    }
  }

  return @packages;
}

sub latest_distributions {
  my ($self, $id) = @_;

  return unless $id;

  my @packages;
  foreach my $package ( cpan_packages->latest_distributions ) {
    if ( $package->cpanid eq $id ) {
      push @packages, $package;
    }
  }

  return @packages;
}

sub avatar_url {
  my ($self, $id, %options) = @_;

  return unless $id;

  require Gravatar::URL;
  my $author = cpan_authors->author($id) or return;

  return Gravatar::URL::gravatar_url( email => $author->email, %options );
}

sub kwalitee {
  my ($self, $id) = @_;

  return unless $id;

  require Acme::CPANAuthors::Utils::Kwalitee;
  return  Acme::CPANAuthors::Utils::Kwalitee->fetch($id);
}

sub look_for {
  my ($self, $id_or_name) = @_;

  return unless defined $id_or_name;
  unless (ref $id_or_name eq 'Regexp') {
    $id_or_name = qr/$id_or_name/i;
  }

  my @found;
  foreach my $category ( _list_categories() ) {
    my %authors = _get_authors_of($category);
    while ( my ($id, $name) = each %authors ) {
      if ($id =~ /$id_or_name/ or $name =~ /$id_or_name/) {
        push @found, {
          id       => $id,
          name     => $name,
          category => $category,
        };
      }
    }
  }
  return @found;
}

sub _list_categories {
  require Module::Find;
  return grep { $_ !~ /^(?:Register|Utils|Not|Search)$/ }
         map  { s/^Acme::CPANAuthors:://; $_ }
         Module::Find::findsubmod( 'Acme::CPANAuthors' );
}

sub _get_authors_of {
  my $category = shift;

  $category =~ s/^Acme::CPANAuthors:://;

  return if $category =~ /^(?:Register|Utils|Search)$/;

  my $package = "Acme::CPANAuthors\::$category";
  eval "require $package";
  if ( $@ ) {
    carp "$category CPAN Authors are not registered yet: $@";
    return;
  }
  $package->authors;
}

1;

__END__