App::Nopaste - easy access to any pastebin

App-Nopaste documentation Contained in the App-Nopaste distribution.

Index

Code Index:

NAME

Top

App::Nopaste - easy access to any pastebin

SYNOPSIS

Top

    use App::Nopaste 'nopaste';

    my $url = nopaste(q{
        perl -wle 'print "Prime" if (1 x shift) !~ /^1?$|^(11+?)\1+$/' [number]
    });

    # or on the command line:
    nopaste test.pl
    => http://pastebin.com/fcba51f

DESCRIPTION

Top

Pastebins (also known as nopaste sites) let you post text, usually code, for public viewing. They're used a lot in IRC channels to show code that would normally be too long to give directly in the channel (hence the name nopaste).

Each pastebin is slightly different. When one pastebin goes down (I'm looking at you, http://paste.husk.org), then you have to find a new one. And if you usually use a script to publish text, then it's too much hassle.

This module aims to smooth out the differences between pastebins, and provides redundancy: if one site doesn't work, it just tries a different one.

It's also modular: you only need to put on CPAN a App::Nopaste::Service::Foo module and anyone can begin using it.

INTERFACE

Top

CLI

See the documentation in App::Nopaste::Command.

nopaste

    use App::Nopaste 'nopaste';

    my $url = nopaste(
        text => "Full text to paste (the only mandatory argument)",
        desc => "A short description of the paste",
        nick => "Your nickname",
        lang => "perl",
        chan => "#moose",

        # this is the default, but maybe you want to do something different
        error_handler => sub {
            my ($error, $service) = @_;
            warn "$service: $error";
        },

        warn_handler => sub {
            my ($warning, $service) = @_;
            warn "$service: $warning";
        },

        # you may specify the services to use - but you don't have to
        services => ["Shadowcat", "Gist"],
    );

    print $url if $url;

The nopaste function will return the URL of the paste on success, or undef on failure.

For each failure, the error_handler argument is invoked with the error message and the service that issued it.

For each warning, the warn_handler argument is invoked with the warning message and the service that issued it.

SEE ALSO

Top

WebService::NoPaste, WWW::Pastebin::PastebinCom::Create, Devel::REPL::Plugin::Nopaste

AUTHOR

Top

Shawn M Moore, sartak@gmail.com

COPYRIGHT AND LICENSE

Top

Copyright 2008-2010 Shawn M Moore.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

App-Nopaste documentation Contained in the App-Nopaste distribution. 
package App::Nopaste;
use strict;
use warnings;
use 5.008003;
use Module::Pluggable search_path => 'App::Nopaste::Service';

use base 'Exporter';
our @EXPORT_OK = 'nopaste';

our $VERSION = '0.28';

sub nopaste {
    # process arguments
    # allow "nopaste($text)"
    unshift @_, 'text' if @_ == 1;

    # only look for $self if we have odd number of arguments
    my $self;
    $self = @_ % 2 ? shift : __PACKAGE__;

    # everything else
    my %args = @_;

    $args{services} = defined($ENV{NOPASTE_SERVICES})
                   && [split ' ', $ENV{NOPASTE_SERVICES}]
                        if !defined($args{services});

    $args{nick} = $ENV{NOPASTE_NICK} || $ENV{USER}
        if !defined($args{nick});


    my $using_default = 0;
    unless (ref($args{services}) eq 'ARRAY' && @{$args{services}}) {
        $using_default = 1;
        $args{services} = [ $self->plugins ];
    }

    @{ $args{services} }
        or Carp::croak "No App::Nopaste::Service module found";

    defined $args{text}
        or Carp::croak "You must specify the text to nopaste";

    $args{error_handler} ||= sub { warn "$_[1]: $_[0]" };

    # try to paste to each service in order
    for my $service (@{ $args{services} }) {
        $service = "App::Nopaste::Service::$service"
            unless $service =~ /^App::Nopaste::Service/;

        no warnings 'exiting';
        my @ret = eval {

            local $SIG{__WARN__} = sub {
                $args{warn_handler}->($_[0], $service);
            } if $args{warn_handler};

            (my $file = "$service.pm") =~ s{::}{/}g;
            require $file;
            next unless $service->available;
            next if $using_default && $service->forbid_in_default;
            $service->nopaste(%args);
        };

        @ret = (0, $@) if $@;

        # success!
        return $ret[1] if $ret[0];

        # failure!
        $args{error_handler}->($ret[1], $service);
    }

    Carp::croak "No available App::Nopaste::Service modules found";
}

1;

__END__