App::Perldoc::Search::_Parser - Pod parser for extracting NAME and searching for matchs

  my $parser = App::Perldoc::Search::_Parser->new;
  $parser->{pattern} = qr/thing_to_search_for/;
  $parser->parse_from_filehandle( $fh );

  if ( $parser->{matched} ) {
      print "$parser->{name}\n";
  }

package App::Perldoc::Search::_Parser;
BEGIN {
  $App::Perldoc::Search::_Parser::VERSION = '0.07';
}

use 5.006;
use strict;
use warnings;
no warnings 'uninitialized';
use Pod::Parser ();
our @ISA = 'Pod::Parser';

sub command {
    my ( $self, $cmd, $text, $line_num, $pod_para ) = @_;

    # Check for "=head1 NAME"
    $self->{expect_name} =
        $cmd =~ /^head\d+$/
        && $text =~ /^\s*NAME\b/;

    # Check our pattern.
    if ( length $self->{pattern} ) {
        ++$self->{matched} while $text =~ /$self->{pattern}/g;
    }

    return;
}

sub verbatim  {
    my ( $self, $text ) = @_;

    # Check our pattern.
    if ( length $self->{pattern} ) {
       ++  $self->{matched} while $text =~ /$self->{pattern}/g;
    }

    return;
}

sub textblock {
    my ( $self, $text, $line_num ) = @_;

    # Check our pattern.
    if ( length $self->{pattern} ) {
        ++$self->{matched} while $text =~ /$self->{pattern}/g;
    }

    # If we recently found "=head1 NAME" then look for a name.
    if ( $self->{expect_name} ) {
        $self->{expect_name} = 0;

        $text =~ s/^\s+//;
        $text =~ s/\s+$//;
        $self->{name} ||= $text;
    }

    return;
}



q(Soviet Jesus's gift at Christmas of a blow-up doll to Debbie would always turn to be the most enigmatic);