Authen::Simple::FTP - Simple FTP authentication

    use Authen::Simple::FTP;

    my $ftp = Authen::Simple::FTP->new( 
        host => 'ftp.company.com'
    );

    if ( $ftp->authenticate( $username, $password ) ) {
        # successfull authentication
    }

    # or as a mod_perl Authen handler

    PerlModule Authen::Simple::Apache
    PerlModule Authen::Simple::FTP

    PerlSetVar AuthenSimpleFTP_host "ftp.company.com"

    <Location /protected>
      PerlAuthenHandler Authen::Simple::FTP
      AuthType          Basic
      AuthName          "Protected Area"
      Require           valid-user
    </Location>

package Authen::Simple::FTP;

use strict;
use warnings;
use base 'Authen::Simple::Adapter';

use Net::FTP;
use Params::Validate qw[];

our $VERSION = 0.2;

__PACKAGE__->options({
    host => {
        type     => Params::Validate::SCALAR,
        default  => 'localhost',
        optional => 1
    },
    port => {
        type     => Params::Validate::SCALAR,
        default  => 21,
        optional => 1
    },
    timeout => {
        type     => Params::Validate::SCALAR,
        default  => 60,
        optional => 1
    }
});

sub check {
    my ( $self, $username, $password ) = @_;

    my $connection = Net::FTP->new(
        Host    => $self->host,
        Port    => $self->port,
        Timeout => $self->timeout
    );

    unless ( defined $connection ) {

        my $host   = $self->host;
        my $reason = $@ || $! || 'Unknown reason';

        $self->log->error( qq/Failed to connect to '$host'. Reason: '$reason'/ )
          if $self->log;

        return 0;
    }

    unless ( $connection->login( $username, $password ) ) {

        chomp( my $message = $connection->message || 'Unknown reason' );
        
        $self->log->debug( qq/Failed to authenticate user '$username'. Reason: '$message'/ )
          if $self->log;

        return 0;
    }

    $self->log->debug( qq/Successfully authenticated user '$username'./ )
      if $self->log;

    return 1;
}

1;

__END__