B::JVM::Jasmin::CompileState - Internal package used by B::JVM::Jasmin to keep state of compilation

  use B::JVM::Jasmin::CompileState;

  my $state = new B::JVM::Jasmin::CompileState([HASHREF]);

# CompileState.pm                                                  -*- Perl -*-
#
#   Copyright (C) 1999, Bradley M. Kuhn, All Rights Reserved.
#
# You may distribute under the terms of either the GNU General Public License
# or the Artistic License, as specified in the LICENSE file that was shipped
# with this distribution.


package B::JVM::Jasmin::CompileState;

use 5.000562;

use strict;
use warnings;

use vars qw(@ISA $VERSION);

$VERSION = "0.02";

@ISA = qw();

###############################################################################

use Carp;
use File::Spec::Functions;
use IO::File;
use B::JVM::Jasmin::Emit;

###############################################################################

#-----------------------------------------------------------------------------

sub new {
  my $proto = shift;
  my $class = ref($proto) || $proto;
  my $self  = shift;

  croak("CompileState not initialized correctly")
    unless (ref($self) eq "HASH");

  my(@validUserParameters) = qw(mainClassName currentPackage outputDirectory
                                keepIntermediateFiles);
  my(%validUserParameters);
  @validUserParameters{@validUserParameters} = 1 .. @validUserParameters;

  # Set up defaults we require

  $self->{mainClassName} = "Main"  unless defined $self->{mainClassName};
  $self->{outputDirectory} = curdir() unless defined $self->{outputDirectory};

  $self->{outputDirectory} = canonpath($self->{outputDirectory}, 1);

  # First, check to make sure parameters given were correct

  foreach my $parameter (keys %{$self}) {
    croak("invalid parameter: $parameter")
      unless defined $validUserParameters{$parameter};
  }
  bless $self, $class;
  $self->createNewFile("main", $self->{mainClassName});

  return $self;
}

#-----------------------------------------------------------------------------

sub createNewFile {
  my($self, $packageName, $className) = @_;

  # Make sure we haven't already set this package up
  return if defined $self->{Package}->{$packageName};

  unless (defined $className) {
    $className = $packageName;
    $className =~ s/::/_/g;
  }
  my $fileName = catfile($self->{outputDirectory}, "${className}.jasmin");

  my $fh = new IO::File;
  open($fh, ">$fileName") || croak "unable to open $fileName: $!";

  $self->{Package}->{$packageName}->{FH} = $fh;
  $self->{Package}->{$packageName}->{fileName} = $fileName;
  $self->{Package}->{$packageName}->{emitter}  =
    new B::JVM::Jasmin::Emit($fh, $fileName);

  $self->{Package}->{$packageName}->{emitter}->source("${className}.jasmin");
  $self->{Package}->{$packageName}->{emitter}->class("public", $className);
  $self->{Package}->{$packageName}->{emitter}->super("java/lang/Object");

#  This isn't right!  I think perljvm program will need to clear these out
#  push(@{$self->{CleanupFiles}}, $fileName)
#    unless $self->{keepIntermediateFiles};

  return $self;
}
#-----------------------------------------------------------------------------

sub emit {
  my($self, $packageName) = @_;

  unless (defined $packageName) {
    $packageName = $self->{currentPackage};
    croak "cannot emit; there appears to be no currentPackage set"
      unless (defined $packageName);
  }
  return $self->{Package}->{$packageName}->{emitter};
}

#-----------------------------------------------------------------------------

sub setCurrentMethod {
  my($self, $methodName) = @_;
  
  $self->{currentMethod} = $methodName;
}

#-----------------------------------------------------------------------------

sub setCurrentPackage {
  my($self, $packageName) = @_;
  
  $self->{currentPackage} = $packageName;
}
#-----------------------------------------------------------------------------

sub clearCurrentMethod {
  my($self) = @_;
  
  $self->{currentMethod} = undef;
}
#-----------------------------------------------------------------------------

sub getCurrentMethod {
  my($self) = @_;
  
  return $self->{currentMethod};
}


#-----------------------------------------------------------------------------

sub DESTROY {
  my $self = shift;

  unlink(@{$self->{CleanupFiles}}) if (defined $self->{CleanupFiles});
}
###############################################################################
1;
__END__