Badger::Log - log for errors, warnings and other messages

Badger documentation Contained in the Badger distribution.

Index

Code Index:

NAME

Top

Badger::Log - log for errors, warnings and other messages

SYNOPSIS

Top

    use Badger::Log;

    my $log = Badger::Log->new({
        debug => 0,      # ignore debug messages
        info  => 1,      # print info messages
        warn  => \@warn, # add warnings to list
        error => $log2,  # delegate errors to $log2
        fatal => sub {   # custom fatal error handler
            my $message = shift;
            print "FATAL ERROR: $message\n";
        },
    });

    $log->debug('a debug message');
    $log->info('an info message');
    $log->warn('a warning message');
    $log->error('an error message');
    $log->fatal('a fatal error message');

DESCRIPTION

Top

This module defines a simple base class module for logging messages generated by an application. It is intentionally very simple in design, providing the bare minimum in functionality with the possibility for extension by subclassing.

It offers little, if anything, over the many other fine logging modules available from CPAN. It exists to provide a basic logging facility that integrates cleanly with, and can be bundled up with the other Badger modules so that you've got something that works "out of the box".

There are five message categories:

debug

A debugging message.

info

A message providing some general information.

warn

A warning message.

error

An error message.

fatal

A fatal error message.

CONFIGURATION OPTIONS

Top

debug

Flag to indicate if debugging messages should be generated and output. The default value is 0. It can be set to 1 to enable debugging messages or to one of the other reference values described in the documentation for the new() method.

info

Flag to indicate if information messages should be generated and output. The default value is 0. It can be set to 1 to enable information messages or to one of the other reference values described in the documentation for the new() method.

warn

Flag to indicate if warning messages should be generated and output. The default value is 1. It can be set to 0 to disable warning messages or to one of the other reference values described in the documentation for the new() method.

error

Flag to indicate if error messages should be generated and output. The default value is 1. It can be set to 0 to disable error messages or to one of the other reference values described in the documentation for the new() method.

fatal

Flag to indicate if fatal messages should be generated and output. The default value is 1. It can be set to 0 to disable fatal error messages (at your own peril) or to one of the other reference values described in the documentation for the new() method.

format

This option can be used to define a different log message format. 

    my $log = Badger::Log->new(
        format => '[<level>] [<time>] <message>',
    );

The default message format is:

    [<time>] [<system>] [<level>] <message>

The <XXX> snippets are replaced with their equivalent values:

    time        The current local time
    system      A system identifier, defaults to 'Badger'
    level       The message level: debug, info, warn, error or fatal
    message     The log message itself

The format can also be set using a $FORMAT package variable in a subclass of Badger::Log.

    package Your::Log::Module;
    use base 'Badger::Log';
    our $FORMAT = '[<level>] [<time>] <message>';
    1;

system

A system identifier which is inserted into each message via the <system> snippet. See format for further information. The default value is Badger.

    my $log = Badger::Log->new(
        system => 'MyApp',
    );

The system identifier can also be set using a $SYSTEM package variable in a subclass of Badger::Log.

    package Your::Log::Module;
    use base 'Badger::Log';
    our $SYSTEM = 'MyApp';
    1;

METHODS

Top

new(\%options)

Constructor method which creates a new Badger::Log object. It accepts a list of named parameters or reference to hash of configuration options that define how each message type should be handled.

    my $log = Badger::Log->new({
        debug => 0,      # ignore debug messages
        info  => 1,      # print info messages
        warn  => \@warn, # add warnings to list
        error => $log2,  # delegate errors to $log2
        fatal => sub {   # custom fatal error handler
            my $message = shift;
            print "FATAL ERROR: $message\n";
        },
    });

Each message type can be set to 0 to ignore messages or 1 to have them printed to STDERR. They can also be set to reference a list (the message is appended to the list), a subroutine (which is called, passing the message as an argument), or any object which implements a log() method (to which the message is delegated).

debug($message)

Generate a debugging message.

    $log->debug('The cat sat on the mat');

info($message)

Generate an information message.

    $log->info('The pod doors are closed');

warn($message)

Generate a warning message.

    $log->warn('The pod doors are opening');

error($message)

Generate an error message.

    $log->error("I'm sorry Dave, I can't do that');

fatal($message)

Generate a fatal error message.

    $log->fatal('HAL is dead, aborting mission');

debug_msg($format,@args)

This method uses the message() method inherited from Badger::Base to generate a debugging message from the arguments provided. To use this facility you first need to create your own logging subclass which defines the message formats that you want to use.

    package Your::Log;
    use base 'Badger::Log';

    our $MESSAGES = {
        denied => "Denied attempt by %s to %s",
    };

    1;

You can now use your logging module like so:

    use Your::Log;
    my $log = Your::Log->new;

    $log->debug_msg( denied => 'Arthur', 'make tea' );

The log message generated will look something like this:

# TODO

info_msg($format,@args)

This method uses the message() method inherited from Badger::Base to generate an info message from the arguments provided. See debug_msg() for an example of using message formats.

warn_msg($format,@args)

This method uses the message() method inherited from Badger::Base to generate a warning message from the arguments provided. See debug_msg() for an example of using message formats.

error_msg($format,@args)

This method uses the message() method inherited from Badger::Base to generate an error message from the arguments provided. See debug_msg() for an example of using message formats.

fatal_msg($format,@args)

This method uses the message() method inherited from Badger::Base to generate a fatal error message from the arguments provided. See debug_msg() for an example of using message formats.

log($level, $message)

This is the general-purpose logging method that the above methods call.

    $log->log( info => 'star child is here' );

level($level, $action)

This method is used to get or set the action for a particular level. When called with a single argument, it returns the current action for that level.

    my $debug = $log->level('debug');

When called with two arguments it sets the action for the log level to the second argument.

    $log->level( debug => 0 );      # disable
    $log->level( info  => 1 );      # enable
    $log->level( warn  => $list );  # push to list
    $log->level( error => $code );  # call code
    $log->level( fatal => $log2 );  # delegate to another log

enable($level)

This method can be used to enable one or more logging levels.

    $log->enable('debug', 'info', 'warn');

disable($level)

This method can be used to disable one or more logging levels.

    $log->disable('error', 'fatal');

INTERNAL METHODS

Top

_error_msg($format,@args)

The error_msg() method redefines the error_msg() method inherited from Badger::Base (which can be considered both a bug and a feature). The internal _error_msg() method effectively bypasses the new method and performs the same functionality as the base class method, in throwing an error as an exception.

_fatal_msg($format,@args)

As per _error_msg(), this method provides access to the functionality of the fatal_msg() method in Badger::Base.

AUTHOR

Top

Andy Wardley http://wardley.org/

COPYRIGHT

Top

Copyright (C) 2005-2009 Andy Wardley. All Rights Reserved.

This module is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

SEE ALSO

Top

Badger::Log::File

Badger documentation Contained in the Badger distribution. 
#========================================================================
#
# Badger::Log
#
# DESCRIPTION
#   A simple base class logging module.
#
# AUTHOR
#   Andy Wardley   <abw@wardley.org>
#
#========================================================================

package Badger::Log;

use Badger::Class
    version   => 0.01,
    base      => 'Badger::Prototype',
    import    => 'class',
    utils     => 'blessed',
    config    => 'system|class:SYSTEM format|class:FORMAT',
    constants => 'ARRAY CODE',
    constant  => {
        MSG   => '_msg',        # suffix for message methods, e.g. warn_msg()
        LOG   => 'log',         # method a delegate must implement
    },
    vars      => {
        SYSTEM => 'Badger',
        FORMAT => '[<time>] [<system>] [<level>] <message>',
        LEVELS => {
            debug => 0,
            info  => 0,
            warn  => 1,
            error => 1,
            fatal => 1,
        }
    },
    messages  => {
        bad_level => 'Invalid logging level: %s',
    };
    


class->methods(
    # Our init method is called init_log() so that we can use Badger::Log as 
    # a mixin or base class without worrying about the init() method clashing 
    # with init() methods from other base classes or mixins.  We create an 
    # alias from init() to init_log() so that it also Just Works[tm] as a 
    # stand-alone object
    init   => \&init_log,

    # Now we define two methods for each logging level.  The first expects
    # a pre-formatted output message (e.g. debug(), info(), warn(), etc)
    # the second additionally wraps around the message() method inherited
    # from Badger::Base (eg. debug_msg(), info_msg(), warn_msg(), etc)
    map {
        my $level = $_;             # lexical variable for closure
        
        $level => sub {
            my $self = shift;
            return $self->{ $level } unless @_;
            $self->log($level, @_) 
                if $self->{ $level };
        },

        ($level.MSG) => sub {
            my $self = shift;
            return $self->{ $level } unless @_;
            $self->log($level, $self->message(@_)) 
                if $self->{ $level };
        }
    }
    keys %$LEVELS
);


sub init_log {
    my ($self, $config) = @_;
    my $class  = $self->class;
    my $levels = $class->hash_vars( LEVELS => $config->{ levels } );
    
    # populate $self for each level in $LEVEL using the 
    # value in $config, or the default in $LEVEL
    while (my ($level, $default) = each %$levels) {
        $self->{ $level } = 
            defined $config->{ $level }
                  ? $config->{ $level } 
                  : $levels->{ $level };
    }

    # call the auto-generated configure() method to update $self from $config
    $self->configure($config);

    return $self;
}

sub log {
    my $self    = shift;
    my $level   = shift;
    my $action  = $self->{ $level };
    my $message = join('', @_);
    my $method;

    return $self->_fatal_msg( bad_level => $level )
        unless defined $action;
        
    # depending on what the $action is set to, we add the message to
    # an array, call a code reference, delegate to another log object,
    # print or ignore the mesage

    if (ref $action eq ARRAY) {
        push(@$action, $message);
    }
    elsif (ref $action eq CODE) {
        &$action($level, $message);
    }
    elsif (blessed $action && ($method = $action->can(LOG))) {
        $method->($action, $level, $message);
    }
    elsif ($action) {
        warn $self->format($level, $message), "\n";
    }
}

sub format {
    my $self = shift;
    my $args = {
        time    => scalar(localtime(time)),
        system  => $self->{ system },
        level   => shift,
        message => shift,
    };
    my $format = $self->{ format };
    $format =~ 
            s/<(\w+)>/
                            defined $args->{ $1 } 
                                        ? $args->{ $1 }
                                        : "<$1>"
                        /eg;
    return $format;
}

sub level {
    my $self  = shift;
    my $level = shift;
    return $self->_fatal_msg( bad_level => $level )
        unless exists $LEVELS->{ $level };
    return @_ ? ($self->{ $level } = shift) : $self->{ $level };
}

sub enable {
    my $self = shift;
    $self->level($_ => 1) for @_;
}

sub disable {
    my $self = shift;
    $self->level($_ => 0) for @_;
}

sub _error_msg {
    my $self = shift;
    $self->Badger::Base::error(
        $self->Badger::Base::message(@_)
    );
}

sub _fatal_msg {
    my $self = shift;
    $self->Badger::Base::fatal(
        $self->Badger::Base::message(@_)
    );
}


1;

__END__


# Local Variables:
# mode: perl
# perl-indent-level: 4
# indent-tabs-mode: nil
# End:
#
# vim: expandtab shiftwidth=4: