Bio::Graphics::Glyph::hybrid_plot - An xyplot plot drawing dual graph using data from two wiggle files per track

 2L 400 500 0.5
 2L 501 600 0.5
 2L 601 700 0.4
 2L 701 800 0.1
 2L 800 900 0.1

 Name        Value        Description
 ----        -----        -----------

 wigfileA    path name    Path to a Bio::Graphics::Wiggle file for accumulated vales in 10-base bins

 wigfileB    path name    Path to a Bio::Graphics::Wiggle file for max values in 10-base bins

 fasta       path name    Path to fasta file to enable BigWig drawing

 u_method    method name  Use method of [method name] to identify individual features (like alignment matches) 
                          to show at high zoom level. By default it is set to 'match'    

 Please report them.

package Bio::Graphics::Glyph::hybrid_plot;

use strict;
use base qw(Bio::Graphics::Glyph::wiggle_xyplot Bio::Graphics::Glyph::smoothing);
use constant DEBUG=>0;
use constant NEGCOL=>"orange";
use constant POSCOL=>"blue";

our $VERSION = '1.0';

sub my_options {
    {   
        min_score => [
            'integer',
            undef,
            "Minimum value of the signal graph feature's \"score\" attribute."],
        max_score => [
            'integer',
            undef,
            "Maximum value of the signal graph feature's \"score\" attribute."],
        flip_sign => [
            'boolean',
            0,
            "Optionally flip the signal for wigfileB (if the scores are positive but we wish to paint the signal along negative y-axis)"]
    };
}

sub my_description {
    return <<END;
This glyph draws signal graph (wiggle_xyplot) using wiggle or BigWig files
requires a special load gff file that uses attributes 'wigfileA' and 'wigfileB'
For BigWig support it is also required to have 'fasta' attribute set to point
to a fasta file for your organism of interest

Example:

2L  test   hybrid    5407   23011573    .     .     .     Name=Experiment 1;wigfileA=SomeWigFile1.wigdb;wigfileB=SomeWigFile2.wigdb

END
}

#Checking the method for individual features (RNA-Seq reads)
sub _check_uni {
 return shift->option('u_method') || 'match';
}


# Override height and pad functions (needed to correctly space features with different sources):
sub height {
  my $self = shift;
  my $h    = $self->SUPER::height;
  return $self->feature->method eq $self->_check_uni ? 3 : $h;
}

sub pad_top {
  my $self = shift;
  return $self->feature->method eq $self->_check_uni ? 0 : 4;
}

sub pad_bottom {
  my $self = shift;
  return $self->feature->method eq $self->_check_uni ? 0 : 4;
}

# we override the draw method so that it dynamically creates the parts needed
# from the wig file rather than trying to fetch them from the database
sub draw {
 
 my $self = shift;
 my ($gd,$dx,$dy) = @_;
 my ($left,$top,$right,$bottom) = $self->calculate_boundaries($dx,$dy);
 my $height   = $bottom - $top;
 my $feature  = $self->feature;
 my $set_flip = $self->option('flip_sign') | 0;
 
 
 #Draw individual features for reads (unlike wiggle features reads will have scores)
 my $t_id = $feature->method;
 if($t_id && $t_id eq $self->_check_uni){return Bio::Graphics::Glyph::generic::draw_component($self,@_);}

 #Draw multiple graph if we don't have a score
 my @wiggles = ();
 foreach ('A'..'Z') {
   my $filename = 'wigfile'.$_;
   my ($wiggle) = $feature->get_tag_values('wigfile'.$_);
   push (@wiggles, $wiggle);
 }

 my ($fasta)   = $feature->get_tag_values('fasta');
 my($scale,$y_origin,$min_score,$max_score);

 $self->panel->startGroup($gd);

 #Depending on what we have (wiggle or BigWig) pick the way to paint the signal graph
 for(my $w = 0; $w < @wiggles; $w++){
  if ($w > 0) {
    $self->configure(-pos_color, NEGCOL);
    $self->configure(-no_grid, 1);
  } else {
    $self->configure(-pos_color, POSCOL);
  }
  if ($wiggles[$w] =~ /\.wi\w{1,3}$/) {
   $self->draw_wigfile($feature,$wiggles[$w],@_);
  } elsif ($wiggles[$w] =~ /\.bw$/ && $fasta) {
   my $flip = ($w > 0 && $set_flip) ? -1 : 1;
   use Bio::DB::BigWig 'binMean';
   use Bio::DB::Sam;
   my $wig = Bio::DB::BigWig->new(-bigwig => "$wiggles[$w]",
                                  -fasta  => Bio::DB::Sam::Fai->open("$fasta"));

   my ($summary) = $wig->features(-seq_id => $feature->segment->ref,
                                  -start  => $self->panel->start,
                                  -end    => $self->panel->end,
                                  -type   => 'summary');
   
   my $stats = $summary->statistical_summary($self->width);
   my @vals  = map {$_->{validCount} ? $_->{sumData}/$_->{validCount}*$flip:0} @$stats;
   $self->draw_coverage($self,\@vals,@_);
  }
 }
}

1;

__END__