Bio::Graphics::Glyph::track - The "track" glyph

  See L<Bio::Graphics::Panel> and L<Bio::Graphics::Glyph>.

package Bio::Graphics::Glyph::track;

use strict;
use base qw(Bio::Graphics::Glyph);

# track sets connector to empty
sub connector {
  my $self = shift;
  return $self->SUPER::connector(@_) if $self->all_callbacks;
  return 'none';
}

sub draw {
  my $self = shift;
  my ($gd,$left,$top,$partno,$total_parts) = @_;

  # the clipping code here prevents poorly-behaving glyphs from
  # drawing outside the track
  my @clip;
  if ($gd->can('clip')) {
    @clip = $gd->clip();
    # glyphs are allowed a slop area of ~3 on either side and 6 on the top and bottom
    # in order to spill out over their boundaries.  Beyond this they start overlapping
    # with other glyphs in an ugly way.
    my @cliprect = ($left-$self->panel->pad_left,
		    $top-6,
		    $self->panel->right+$self->panel->pad_right,
		    $top+$self->layout_height+6);
    $gd->clip(@cliprect);
  }

  my @parts = $self->parts;
  for (my $i=0; $i<@parts; $i++) {
    $parts[$i]->draw_highlight($gd,$left,$top);
    $parts[$i]->draw($gd,$left,$top,0,1);
  }

  $gd->clip(@clip) if @clip;
}

# do nothing for components
# sub draw_component { }

sub bump { 
    my $self = shift;
    return 1 if $self->option('group_subtracks');
    my $bump = $self->SUPER::bump;
    return 1  if $bump eq 'fast' or $bump == 3;
    return $bump;
}

1;


__END__