Bio::Matrix::IO::mlagan - A parser for the mlagan substitution matrix

  use Bio::Matrix::IO;
  my $parser = Bio::Matrix::IO->new(-format => 'mlagan',
                                   -file   => 'nucmatrix.txt');
  my $matrix = $parser->next_matrix;
  my $gap_open = $parser->gap_open;
  my $gap_continue = $parser->gap_continue;

  bioperl-l@bioperl.org                  - General discussion
  http://bioperl.org/wiki/Mailing_lists  - About the mailing lists

  https://redmine.open-bio.org/projects/bioperl/

 Title   : new
 Usage   : my $obj = Bio::Matrix::IO::mlagan->new();
 Function: Builds a new Bio::Matrix::IO::mlagan object 
 Returns : an instance of Bio::Matrix::IO::mlagan
 Args    :

 Title   : next_matrix
 Usage   : my $matrix = $obj->next_matrix();
 Function: parses a matrix file
 Returns : L<Bio::Matrix::Mlagan>
 Args    : none

 Title   : write_matrix
 Usage   : $obj->write_matrix($matrix)
 Function: Write out a matrix in mlagan format
 Returns : n/a
 Args    : L<Bio::Matrix::Generic>

#
# BioPerl module for Bio::Matrix::IO::mlagan
#
# Please direct questions and support issues to <bioperl-l@bioperl.org> 
#
# Cared for by Sendu Bala <bix@sendu.me.uk>
#
# Copyright Sendu Bala
#
# You may distribute this module under the same terms as perl itself

# POD documentation - main docs before the code

# Let the code begin...

package Bio::Matrix::IO::mlagan;
use strict;

use Bio::Matrix::Mlagan;
use base qw(Bio::Matrix::IO);

sub next_matrix {
    my $self = shift;
    
    my (@matrix, $gap_open, $gap_cont);
    while (defined ($_ = $self->_readline)) {
        if (/^[ACGTN\.]/) {
            my (undef, @values) = split;
            push(@matrix, \@values);
        }
        elsif (/^[-\d]/) {
            ($gap_open, $gap_cont) = split;
            last;
        }
    }
    
    @matrix == 6 || $self->throw("Something wrong with file, was it the correct format?");
    
    my $matrix = Bio::Matrix::Mlagan->new(-values => \@matrix,
                                          -gap_open => $gap_open,
                                          -gap_continue => $gap_cont);
    
    return $matrix;
}

sub write_matrix {
    my ($self, $matrix) = @_;
    $matrix || $self->throw("Matrix required as input");
    my $gap_open = $matrix->gap_open;
    my $gap_continue = $matrix->gap_continue;
    
    unless (defined $gap_open && defined $gap_continue) {
        $self->throw("gap_open() and gap_continue() in the supplied matrix object must both be set");
    }
    
    $self->_print("     A    C    G    T    .    N\n");
    
    foreach my $char (qw(A C G T . N)) {
        my @row = $matrix->get_row($char);
        my $row = $char;
        foreach my $val (@row) {
            $row .= " " x (5 - length($val)) . $val;
        }
        
        $self->_print($row."\n");
    }
    
    $self->_print("\n$gap_open $gap_continue");
    
    return;
}

1;