Bio::Symbol::Alphabet - BSANE/BioCORBA compliant symbol list alphabet

BioPerl documentation Contained in the BioPerl distribution.

Index

Code Index:

NAME

Top

Bio::Symbol::Alphabet - BSANE/BioCORBA compliant symbol list alphabet

SYNOPSIS

Top

  {
      my $alphabet = Bio::Symbols::Alphabet->new(-symbols => [ @s ],
  						-subalphabets => [ @alphas ] );

      my @symbols = $alphabet->symbols;
      my @subalphas = $alphabet->alphabets;
      if( $alphabet->contains($symbol) ) {
  	  # do something
      }
  }

DESCRIPTION

Top

Alphabet contains set of symbols, which can be concatenated to form symbol lists. Sequence string, for example, is stringified representation of the symbol list (tokens of symbols).

This module was implemented for the purposes of meeting the BSANE/BioCORBA spec 0.3 only.

FEEDBACK

Top

Mailing Lists

User feedback is an integral part of the evolution of this and other Bioperl modules. Send your comments and suggestions preferably to the Bioperl mailing list. Your participation is much appreciated.

  bioperl-l@bioperl.org                  - General discussion
  http://bioperl.org/wiki/Mailing_lists  - About the mailing lists

Support

Please direct usage questions or support issues to the mailing list:

bioperl-l@bioperl.org

rather than to the module maintainer directly. Many experienced and reponsive experts will be able look at the problem and quickly address it. Please include a thorough description of the problem with code and data examples if at all possible.

Reporting Bugs

Report bugs to the Bioperl bug tracking system to help us keep track of the bugs and their resolution. Bug reports can be submitted via the web:

  https://redmine.open-bio.org/projects/bioperl/

AUTHOR - Jason Stajich

Top

Email jason@bioperl.org

APPENDIX

Top

The rest of the documentation details each of the object methods. Internal methods are usually preceded with a _

new

 Title   : new
 Usage   : my $obj = Bio::Symbol::Alphabet->new();
 Function: Builds a new Bio::Symbol::Alphabet object 
 Returns : Bio::Symbol::Alphabet
 Args    : -symbols  => Array ref of Bio::Symbol::SymbolI objects
           -subalphas=> Array ref of Bio::Symbol::AlphabetI objects 
                        representing sub alphabets

AlphabetI Interface methods

symbols

 Title   : symbols
 Usage   : my @symbols = $alphabet->symbols();
 Function: Get/Set Symbol list for an alphabet
           List of symbols, which make up this alphabet.
 Returns : Array of Bio::Symbol::SymbolI objects
 Args    : (optionalalphabets) Array of Bio::Symbol::SymbolI objects

alphabets

 Title   : alphabets
 Usage   : my @alphabets = $alphabet->alphabets();
 Function: Get/Set Sub Alphabet list for an alphabet 
           Sub-alphabets. E.g. codons made from DNAxDNAxDNA alphabets
 Returns : Array of Bio::Symbol::AlphabetI objects
 Args    : (optional) Array of Bio::Symbol::AlphabetI objects

contains

 Title   : contains
 Usage   : if($alphabet->contains($symbol)) { }
 Function: Tests of Symbol is contained in this alphabet
 Returns : Boolean
 Args    : Bio::Symbol::SymbolI
BioPerl documentation Contained in the BioPerl distribution. 
#
# BioPerl module for Bio::Symbol::Alphabet
#
# Please direct questions and support issues to <bioperl-l@bioperl.org> 
#
# Cared for by Jason Stajich <jason@bioperl.org>
#
# Copyright Jason Stajich
#
# You may distribute this module under the same terms as perl itself

# POD documentation - main docs before the code



# Let the code begin...


package Bio::Symbol::Alphabet;
use strict;

# Object preamble - inherits from Bio::Root::Root


use base qw(Bio::Root::Root Bio::Symbol::AlphabetI);


sub new {
    my($class,@args) = @_;

    my $self = $class->SUPER::new(@args);
    $self->{'_symbols'} = [];
    $self->{'_alphabets'} = [];
    my ($symbols, $subalphas) = $self->_rearrange([qw(SYMBOLS SUBALPHAS)],
						  @args);

    defined $symbols && ref($symbols) =~ /array/i && $self->symbols(@$symbols);
    defined $subalphas && ref($subalphas) =~ /array/i && $self->alphabets(@$subalphas);
    return $self;
}


sub symbols {
    my ($self,@args) = @_;
    if( @args ) { 
	$self->{'_symbols'} = [];
	foreach my $symbol ( @args ) {
	    if( ! defined $symbol || ! ref($symbol) || 
		! $symbol->isa('Bio::Symbol::SymbolI') ) {
		$self->warn("Did not provide a proper Bio::Symbol::SymbolI to method 'symbols' (got $symbol)");
	    } else { 
		push @{$self->{'_symbols'}}, $symbol;
	    }
	}
    }
    return @{$self->{'_symbols'}};
}


sub alphabets {
    my ($self,@args) = @_;
   if( @args ) { 
       $self->{'_alphabets'} = [];
       foreach my $alpha ( @args ) {
	   if( ! $alpha->isa('Bio::Symbol::AlphabetI') ) {
	       $self->warn("Did not provide a proper Bio::Symbol::AlphabetI to method 'alphabets' (got $alpha)");
	   } else { 
	       push @{$self->{'_alphabets'}}, $alpha;
	   }
       }
   }
    return @{$self->{'_alphabets'}};
}


sub contains{
   my ($self,$testsymbol) = @_;
   foreach my $symbol ( $self->symbols ) {
       return 1 if( $symbol->equals($testsymbol) );
   }
   return 0;
}

1;