Bio::Tools::Signalp - parser for Signalp output

 use Bio::Tools::Signalp;

 my $parser = Bio::Tools::Signalp->new(-fh =>$filehandle );

 while( my $sp_feat = $parser->next_result ) {
   if ($sp_feat->score > 0.9) {
      push @likely_sigpep, $sp_feat;
   }
 }

 User feedback is an integral part of the evolution of this and other
 Bioperl modules. Send your comments and suggestions preferably to
 the Bioperl mailing list.  Your participation is much appreciated.

  bioperl-l@bioperl.org                  - General discussion
  http://bioperl.org/wiki/Mailing_lists  - About the mailing lists

  https://redmine.open-bio.org/projects/bioperl/

 Title   : new
 Usage   : my $obj = Bio::Tools::Signalp->new();
 Function: Builds a new Bio::Tools::Signalp object
 Returns : Bio::Tools::Signalp
 Args    : -fh/-file => $val, # for initing input, see Bio::Root::IO

 Title   : next_result
 Usage   : my $feat = $signalp->next_result
 Function: Get the next result set from parser data
 Returns : Bio::SeqFeature::Generic
 Args    : none

 Title   : _parse_hmm_result
 Usage   : $self->_parse_hmm_result(\%feature)
 Function: Internal (not to be used directly)
 Returns : hash of feature values
 Args    : hash of more feature values

 Title   : _create_feature
 Usage   : $self->create_feature(\%feature)
 Function: Internal (not to be used directly)
 Returns : hash of feature values
 Args    : hash of more feature values

 Title   : _seqname
 Usage   : $self->_seqname($name)
 Function: Internal (not to be used directly)
 Returns :
 Args    :

 Title   : _fact1
 Usage   : $self->fact1($fact1)
 Function: Internal (not to be used directly)
 Returns : 
 Args    :

# Parser module for Signalp Bio::Tools::Signalp
#
# 
# Based on the EnsEMBL module
# Bio::EnsEMBL::Pipeline::Runnable::Protein::Signalp originally
# written by Marc Sohrmann (ms2@sanger.ac.uk) Written in BioPipe by
# Please direct questions and support issues to <bioperl-l@bioperl.org> 
#
# Balamurugan Kumarasamy <savikalpa@fugu-sg.org> Cared for by the Fugu
# Informatics team (fuguteam@fugu-sg.org)

# You may distribute this module under the same terms as perl itself
#
# POD documentation - main docs before the code

package Bio::Tools::Signalp;
use strict;

use Bio::SeqFeature::Generic;
use base qw(Bio::Root::Root Bio::Root::IO);

sub new {
      my($class,@args) = @_;

      my $self = $class->SUPER::new(@args);
      $self->_initialize_io(@args);

      return $self;
}

sub next_result {
        my ($self) = @_;
        
        while (my $line=$self->_readline()) {
           chomp $line;
           
           if ($line=~/^\>(\S+)/) {
              $self->_seqname($1);
           }
           elsif ($line=~/max\.\s+Y\s+(\S+)\s+\S+\s+\S+\s+(\S+)/) {
              $self->_fact1($2);
           }
           elsif ($line=~/mean\s+S\s+(\S+)\s+\S+\s+\S+\s+(\S+)/) {
              my $fact2 = $2;
              
              if ($fact2 eq 'YES' and $self->_fact1 eq 'YES') {
                  
                  my $line = $self->_readline();
                  
                  ###########################################
                  # modification to suit new SignalP output
                  ###########################################
					chomp $line;
					#print STDERR "********** <$line>\n";
					if ($line =~ /\s+D\s+.*/) {
				  		$line = $self->_readline();
					}
					#print STDERR "********** <$line>\n";
		  			my $end;
		  		  ###########################################
		  
              
                  if ($line =~ /Most likely cleavage site between pos\.\s+(\d+)/) {
                      my $end = $1;
                      my (%feature);
                      $feature{seq_id} = $self->_seqname;
                      $feature{start} = 1;
                      $feature{end} = $end;
                      $feature{source_tag} = 'Signalp';
                      $feature{primary}= 'signal_peptide';
                      $self->_parse_hmm_result(\%feature);
                      my $new_feat = $self->_create_feature (\%feature);
                      return $new_feat;
                  }
                  else {
                      $self->throw ("parsing problem in signalp");
                  }
                  
              }
           }
        
        }
}

sub _parse_hmm_result {
    my ($self, $feature_hash) = @_;
    while(my $line = $self->_readline){
        chomp $line;
        if($line =~ /Prediction: (.+)$/){
            $feature_hash->{hmmProdiction} = $1;
        }elsif($line =~ /Signal peptide probability: ([0-9\.]+)/){
            $feature_hash->{peptideProb} = $1;
        }elsif($line =~ /Signal anchor probability: ([0-9\.]+)/){
            $feature_hash->{anchorProb} = $1;
            last;
        }
    }
}

sub _create_feature {
    my ($self, $feat) = @_;

    # create feature object
    my $feature = Bio::SeqFeature::Generic->new(
         -seq_id      => $feat->{name},
         -start       => $feat->{start},
         -end         => $feat->{end},
         -score       => $feat->{score},
         -source      => $feat->{source},
         -primary     => $feat->{primary},
         -logic_name  => $feat->{logic_name}, 
    );
           
    $feature->score($feat->{peptideProb});
    $feature->add_tag_value('peptideProb', $feat->{peptideProb});
    $feature->add_tag_value('anchorProb', $feat->{anchorProb});
    $feature->add_tag_value('evalue',$feat->{anchorProb});
    $feature->add_tag_value('percent_id','NULL');
    $feature->add_tag_value("hid",$feat->{primary});
    $feature->add_tag_value('SignalpPrediction', $feat->{hmmProdiction});
    return $feature; 

}

sub _seqname{
    my ($self,$seqname)=@_;

    if (defined$seqname){
        $self->{'seqname'}=$seqname;
    }
    return $self->{'seqname'};
}

sub _fact1{
    my ($self, $fact1)=@_;

    if (defined $fact1){
       $self->{'fact1'}=$fact1;
    }
    return $self->{'fact1'};
}



1;