Business::UTV - Module for retrieiving UTV internet account information

 use Business::UTV;
 my $utv = Business::UTV->login( $id , $password , { "name" => "me" } );
 my $usage = $utv->usage();
 print "Upload = " . $usage->{"upload"} . "MB\n";

 $utv = Business::UTV->login( $id , $password , { "name" => $name }

 my $usage = $utv->usage();
 print "Upload - " . $usage->{"upload"} . "\n";
 print "Download - " . $usage->{"download"} . "\n";

 my ( $total , $calls ) = $utv->current_statement();

 date
 time
 phone_number
 type
 length
 cost

package Business::UTV;

use strict;
use warnings;

use LWP::UserAgent;
use HTTP::Request::Common;
use URI::Escape;

our $VERSION = 0.05;
our $errstr = undef;

sub login
{
	my ( $class , $username , $password , $atts ) = @_;

	errstr( "" );
	
	my $name = $atts->{"name"};
	my $login_url = "https://ssl2.u.tv/clicksilveraccountie/gologin.asp";
	my $usage_url = "https://ssl2.u.tv/clicksilveraccountie/onlineusage.asp?id=$username";
	my $newindex_url = "https://ssl2.u.tv/clicksilveraccountie/newindex.asp";
	
	my $statement_url = "https://ssl2.u.tv/clicksilveraccountie/statementbeta.asp";
	
	my $ua = LWP::UserAgent->new();

	my $login_request = $ua->post( $login_url , 
				{ "id" => $username , "password" => $password } ,
				"Referer" => $newindex_url );

	if( $login_request->is_error() )
	{
		errstr( "Login failed : http problem" );
		return undef;
	}

	my $login = $login_request->content();
	my %data = ();

	unless( $login =~ /\Q$name\E/ )
	{
		errstr( "Login failed : your name '$name' not matched" );
		return undef;
	}

	while( $login =~ /<input\s+type\s*=\s*hidden\s+name\s*=\s*([^ ]+)\s+value\s*=\s*['"]?([^'">]+)['"]?>/ig )
	{
		$data{$1}=$2;
	}
	
	my %self = %$atts;
	
	$self{"ua"} = $ua;
	$self{"login_url"} = $login_url;
	$self{"usage_url"} = $usage_url;
	$self{"statement_url"} = $statement_url;
	
	$self{"username"} = $username;
	$self{"password"} = $password;
	$self{"_data"} = \%data;
	
	bless( \%self , $class );
}


sub usage
{
	my ( $self ) = @_;

	errstr( "" );
	
	my $upload;
	my $download;

	my $usage_request = $self->{"ua"}->get( $self->{"usage_url"} );

        if( $usage_request->is_error() )
        {
                errstr( "Usage failed : http problem" );
                return undef;
        }

	my $usage = $usage_request->content();
	
	if( $usage =~ /Incoming:\s*(\d+(\.\d+)?)MB/ )
	{
		$upload = $1;
	}
	if( $usage =~ /Outgoing:\s*(\d+(\.\d+)?)MB/ )
	{
		$download = $1;
	}

	if( defined($upload) && defined($download) )
	{
		return { "upload" => $upload , "download" => $download };
	}
	else
	{
		errstr( "Could not retrieve upload and download usage" );
		return undef;
	}
}	


sub current_statement
{
	my ( $self ) = @_;

	errstr( "" );
	
	my $total = undef;
	my $mytotal = 0;
	my @calls = ();
	
	my $referer = "https://ssl2.u.tv/clicksilveraccountie/menu.asp" . 
						"?usersname=" . uri_escape( $self->{"_data"}->{"usersname"} ) . 
						"&tariffcode=" . uri_escape( $self->{"_data"}->{"tariffcode"} );

	my $statement_request  = $self->{"ua"}->post( 
					$self->{"statement_url"} , 
					{ "custid" => $self->{"username"} },
					"Referer" => $referer 
					);
	
	my $statement = $statement_request->content();
	$statement =~ s/<font[^>]+>//ig;
	$statement =~ s/<\/font>//ig;
	$statement =~ s/&nbsp;//g;

	while( $statement =~ /<tr[^>]*>(.*?)<\/tr>/isg )
	{
		my $line = $1;
		if( $line =~ /total/i )
		{	
			if( $line =~ /&euro;(.+)\s/ )
			{
				$total = $1;
			}
		}	
	
		my $count = 0;
		my @fields = ();
		my $call = {};
		while( $line =~ /<td[^>]+>(.*?)<\/td>/g )
		{
			if( length($1) > 0 )
			{
				push( @fields  , $1 );
			}
			$count++;
		}

		if( $count == 8 && scalar( @fields ) == 6 && $fields[0] ne "<b><u>Date</u></b>" )
		{
			@$call{ ( "date" , "time" , "phone_number" , "type" , "length" , "cost" ) } = @fields;
			if( $call->{"cost"} eq "FREE!" )
			{
				$call->{"cost"} = 0;
			}
			$mytotal = $mytotal + $call->{"cost"};
			push( @calls , $call );
		}
	}

	if( !defined( $total ) )
	{
		errstr( "Could not find their total" );
		return undef;
	}
	if( abs($total-$mytotal) > 0.1 )
	{
		errstr( "I calculated total of $mytotal but they said total is $total" );
		return undef;
	}
	return ( $total , \@calls );
}

sub errstr
{
	my ( $error ) = @_;
	
	if( defined( $error ) )
	{
		$errstr = $error;
		if( length( $errstr ) )
		{
			warn( $errstr );
		}
		else
		{
			$errstr = undef;
		}
	}
	return $errstr;
}

1;