CDDB::Fake - Fake CDDB entries if you have none

    use CDDB::Fake;
    my $cddb = CDDB::Fake->new("music/Egg/Egg/.nocddb");
    print "Artist: ", $cddb->artist, "\n";
    foreach my $track ( $cddb->tracks ) {
        print "Track ", $track->number, ": ", $track->title, "\n";
    }

    Birelli Lagrene / Standards

       1. C'est Si Bon
       2. Softly, As in a Morning Sunrise
       3. Days of Wine and Roses
      ...
      12. Nuages

    Birelli Lagrene / Standards

       1. C'est Si Bon
          Original version
       2. Softly, As in a Morning Sunrise
          Live recording.
          Probably incomplete.
       3. Days of Wine and Roses
      ...
      12. Nuages

    This album was recorded in the Olympia Studios in Paris.

    use CDDB::File;	# the real one
    use CDDB::Fake;	# the fake one
    use Carp;

    # Return a CDDB::File object if a .cddb file is present, otherwise
    # return a CDDB::Fake onkect from a .nocddb file, if present.

    sub cddb_info($) {
	my $df = shift;
	croak("cddb_info(dir)\n") unless -d $df;
	return CDDB::File->new("$df/.cddb")   if -s "$df/.cddb";
	return CDDB::Fake->new("$df/.nocddb") if -s "$df/.nocddb";
	undef;
    }

# CDDB::Fake.pm -- CDDB File Faker
# RCS Info        : $Id: CDDB-Fake.pm,v 1.5 2004/08/13 13:38:04 jv Exp $
# Author          : Johan Vromans
# Created On      : Tue Mar 25 22:38:32 2003
# Last Modified By: Johan Vromans
# Last Modified On: Fri Aug 13 15:28:55 2004
# Update Count    : 139
# Status          : Unknown, Use with caution!

package CDDB::Fake;

$VERSION = "2.00";

use strict;
use warnings;
use Carp;

sub new {
    my ($pkg, $file) = @_;

    my $self = {
		_title => "",
		_artist => "",
		_extd => "",
	       };

    my $fh;
    if ( ref($file) ) {
	# For testing.
	$fh = $file;
    }
    else {
	open($fh, $file) or croak("$file: $!\n");
    }
    my $off = 150;
    my $state = 0;
    my $va = 0;
    my $to;
    while ( <$fh> ) {
	next unless /\S/;
	s/[\r\n]+$//;

	# State 0: Looking for artist/title.
	if ( $state == 0 ) {
	    if ( /^\s*(.+)\s+\/\s+(.*)/ ) {
		$self->{_artist} = _deblank($1);
		$self->{_title} = _deblank($2);
	    }
	    else {
		# Eponymous.
		$self->{_artist} = $self->{_title}  = _deblank($_);
	    }
	    $va = lc($self->{_artist}) eq "various";
	    $state++;
	    next;
	}

	# State 1: Processing tracks.
	if ( $state == 1 ) {
	    if ( /^\s*(\d+)\.?\s+(.*)/ ) {
		my $tn = 0 + $1;
		my $tt = $2;
		my $tl;
		if ( $tt =~ /^(.*?)\t+ ?(\d+):(\d\d)\s*$/ ) {
		    $tt = _deblank($1);
		    $tl = 60 * $2 + $3;
		    $self->{_length} += $tl;
		}
		else {
		    $tt = _deblank($tt);
		}
		my $art = $self->{_artist};
		if ( $va ) {
		    if ( $tt =~ /^(.+?):\s+(.*)/ ) {
			$art = _deblank($1);
			$tt  = _deblank($2);
		    }
		    elsif ( $tt =~ /^(.+?)\s+\/\s+(.*)/ ) {
			$art = _deblank($1);
			$tt  = _deblank($2);
		    }
		}
		push(@{$self->{_tracks}},
		     $to = CDDB::Fake::Track->new($art, $tn, $tt,
						  $tl, $off, ""));
		$off += 75 * $tl if $tl;
		next;
	    }
	    elsif ( defined($to) && /^\s+(.+)/ ) {
		$to->_extd_append($1);
		next;
	    }
	    else {
		$state++;
	    }
	}

	# State 2: Remainder (ext info).
	if ( $state == 2 ) {
	    $self->{_extd} = $_ . "\n";
	    $state++;
	    next;
	}

	# State 3: Rest of ext info.
	$self->{_extd} .= $_ . "\n";

    }

    $self->{_extd} = _newlines($self->{_extd});

    bless $self, $pkg;
}

sub _deblank {
    my $t = shift;
    for ( $t ) {
	s/^\s+//;
	s/\s+$//;
	s/\s+/ /g;
	return $_;
    }
}

sub _newlines {
    my $t = shift;
    for ( $t ) {
	return $_ unless /\\n/;
	s/\s\n\s/ /g;
	s/\\n/\n/g;
	return $_;
    }
}

sub artist {
    my ($self) = @_;
    $self->{_artist};
}

sub title {
    my ($self) = @_;
    $self->{_title};
}

sub track_count {
    my ($self) = @_;
    scalar(@{$self->{_tracks}});
}

sub tracks {
    my ($self) = @_;
    @{$self->{_tracks}};
}

sub id { "00000000" }

sub all_ids { ("00000000") }

sub year         { "" }
sub genre        { "" }
sub submitted_by { "" }
sub processed_by { "" }
sub revision     { 1  }

sub length {
    my ($self) = @_;
    $self->{_length} || 0;
}

sub extd  {
    my ($self) = @_;
    $self->{_extd} || "";
}

sub as_cddb {
    my ($self) = @_;

    my $ret = "";

    # Writing CDDB data requires some line breaking and such.
    my $out = sub {
	my ($tag, $desc) = @_;
	$desc =~ s/\n/\\n/g;
	$desc =~ s/\\n$//;
	$tag .= "=";
	$desc = $tag . $desc;
	for ( ;; ) {
	    my $t = substr($desc,0,70,$tag);
	    $ret .= $t . "\n";
	    last if $desc eq $tag;
	}
    };

    my @tracks = $self->tracks;

    # Header.
    $ret = "# xmcd 2.0 CD database file\n" .
      "# Copyright (C) 1996,2004 Johan Vromans\n" .
	"#\n";

    if ( $self->length ) {
	$ret .= "# Track frame offsets:\n";
	foreach ( @tracks ) {
	    $ret .= "#\t" . $_->offset . "\n";
	}
	$ret .= "#\n" .
	  "# Disc length: " . $self->length . " seconds\n" .
	    "#\n";
    }

    $out->("DISCID", $self->id);
    $out->("DTITLE", $self->artist . " / " . $self->title);

    my $i;
    for ( $i=0; $i < @tracks; $i++ ) {
	$out->("TTITLE$i", $tracks[$i]->title)
	  if defined $tracks[$i];
    }

    $out->("EXTD", $self->extd);

    for ( $i=0; $i < @tracks; $i++ ) {
	$out->("EXTT$i", $tracks[$i]->extd);
    }
    $out->("PLAYORDER", "");
    $ret;
}

package CDDB::Fake::Track;

sub new {
    my ($pkg, $disc, $num, $tt, $len, $off, $extd) = @_;
    bless [ $disc, $num, $tt, $len, $off, $extd ], $pkg;
}

sub artist { shift->[0] || ""}

sub number { shift->[1] || 0 }

sub title  { shift->[2] || ""}

sub length { shift->[3] || 0}

sub offset { shift->[4] || 0 }

sub extd {
    CDDB::Fake::_newlines(shift->[5] || "");
}

sub _extd_append {
    my ($self, $text) = @_;
    if ( defined($self->[5]) && CORE::length($self->[5]) > 0 ) {
	$self->[5] .= " " . $text;
    }
    else {
	$self->[5] = $text;
    }
}

1;