CGI::Session::ID::incr - CGI::Session ID driver

CGI-Session documentation Contained in the CGI-Session distribution.

Index

Code Index:

NAME

Top

CGI::Session::ID::incr - CGI::Session ID driver

SYNOPSIS

Top

    use CGI::Session;
    $session = CGI::Session->new("id:Incr", undef, {
                                Directory   => '/tmp',
                                IDFile      => '/tmp/cgisession.id',
                                IDInit      => 1000,
                                IDIncr      => 2 });

DESCRIPTION

Top

CGI::Session::ID::incr is to generate auto incrementing Session IDs. Compare it with CGI::Session::ID::md5, where session ids are truly random 32 character long strings. CGI::Session::ID::incr expects the following arguments passed to CGI::Session->new() as the third argument.

IDFile

Location where auto incremented IDs are stored. This attribute is required.

IDInit

Initial value of the ID if it's the first ID to be generated. For example, if you want the ID numbers to start with 1000 as opposed to 0, that's where you should set your value. Default is 0.

IDIncr

How many digits each number should increment by. For example, if you want the first generated id to start with 1000, and each subsequent id to increment by 10, set IDIncr to 10 and IDInit to 1000. Default is 1.

LICENSING

Top

For support and licensing information see CGI::Session

CGI-Session documentation Contained in the CGI-Session distribution. 
package CGI::Session::ID::incr;

# $Id$

use strict;
use File::Spec;
use Carp "croak";
use Fcntl qw( :DEFAULT :flock );
use CGI::Session::ErrorHandler;

$CGI::Session::ID::incr::VERSION = '4.43';
@CGI::Session::ID::incr::ISA     = qw( CGI::Session::ErrorHandler );


sub generate_id {
    my ($self, $args) = @_;

    my $IDFile = $args->{IDFile} or croak "Don't know where to store the id";
    my $IDIncr = $args->{IDIncr} || 1;
    my $IDInit = $args->{IDInit} || 0;

    sysopen(FH, $IDFile, O_RDWR|O_CREAT, 0666) or return $self->set_error("Couldn't open IDFile=>$IDFile: $!");
    flock(FH, LOCK_EX) or return $self->set_error("Couldn't lock IDFile=>$IDFile: $!");
    my $ID = <FH> || $IDInit;
    seek(FH, 0, 0) or return $self->set_error("Couldn't seek IDFile=>$IDFile: $!");
    truncate(FH, 0) or return $self->set_error("Couldn't truncate IDFile=>$IDFile: $!");
    $ID += $IDIncr;
    print FH $ID;
    close(FH) or return $self->set_error("Couldn't close IDFile=>$IDFile: $!");
    return $ID;
}


1;

__END__;