CPAN::DistroBuilder - Create a distro from a bundle or a number of modules from CPAN

  CPAN::DistroBuilder - Create a distro from a bundle or a number of modules from CPAN

  % perl -MCPAN::DistroBuilder -webuild ApacheSDK 0.1 Bundle::Apache

  % perl -MCPAN::DistroBuilder -webuild CoolSDK 0.1 MD5 CGI

  % perl -MCPAN::DistroBuilder -webuild FooBar 0.2 Foo Bar

  % tar -xzvf FooBar-0.2.tar.gz
  % cd FooBar-0.2
  % perl Makefile.PL && make && make test && make install

  % perl Makefile.PL && make && make test && make install

package CPAN::DistroBuilder;

use strict;
use Exporter ();

$CPAN::DistroBuilder::VERSION = '0.01';
@CPAN::DistroBuilder::EXPORT  = qw(build);
@CPAN::DistroBuilder::ISA   = qw(Exporter);

use CPAN;
# must load it now, so we can overload some of the config
CPAN::Config->load;

use File::Find qw(finddepth);
use File::Spec::Functions;

# local config
use lib qw(.);
use CPAN::DistroBuilderConfig;

# override CPAN's default configuration
$CPAN::Config->{$_} = $CPAN::DistroBuilderConfig::Config->{$_}
    for keys %{ $CPAN::DistroBuilderConfig::Config };

my $cpan_dir = $CPAN::Config->{cpan_home};
my $src_dir  = $CPAN::Config->{build_dir};

sub build {
    die "usage: $0 release-name release-version [module(s)] [bundle(s)]\n" 
        unless @ARGV > 2;

    my ($release_name, $version, @bundles) = @ARGV;
    my $package = "$release_name-$version.tar.gz";

    # cleanup from previous session
    del_tree($cpan_dir, $src_dir);

    # fetch all the modules
    report("building in $src_dir");
    CPAN::Shell->force('make', @bundles);

    # make sure distros are clean, before adding to MANIFEST
    CPAN::Shell->clean(@bundles);

    # prepare the MANIFEST file
    add_to_MANIFEST($src_dir, $src_dir);

    write_Makefile_PL($src_dir, $release_name, $version);
    add_to_MANIFEST($src_dir,'Makefile.PL');

    system "(cd $src_dir; perl Makefile.PL && make dist)";

    # mv the product into the current dir
    my $from = catfile $src_dir, $package;
    my $to   = catfile $src_dir, '..', $package;
    rename $from, $to or die "couldn't rename: $from => $to $!";
    report("written $to");
}

# deletes the whole tree(s) or just file(s)
sub del_tree {
    for my $file (@_) {
        next unless -e $file;
        finddepth(sub {-d $_ ? rmdir : unlink; }, $file);
    }
}

# expands the dir|file into a list of files (dirs are skipped)
sub expand_tree {
    my @tree = ();
    for my $file (@_) {
        next unless -e $file;
        push(@tree, $file), next if -f $file;
        finddepth(sub {-f $_ && push @tree, 
                           ($File::Find::name =~ m|$file/(.*)|) }, $file);
    }
    return \@tree;
}

sub write_Makefile_PL {
    my ($dir, $release_name, $version) = @_;
    $dir = '.' unless defined $dir;
    my $file = catfile $dir, 'Makefile.PL';
    open my $fh, '>', $file or die "cannot open $file: $!";
    print $fh qq{use ExtUtils::MakeMaker;\n};
    print $fh qq{WriteMakefile(NAME => "$release_name", VERSION => $version);\n};
    close $fh;
}

# first argument is in what dir MANIFEST is to be appended to
# second argument is a file or directory that should be expanded into
# files, which than added to the MANIFEST file
sub add_to_MANIFEST {
    my ($dir, @files) = @_;
    $dir = '.' unless defined $dir;
    my $file = catfile $dir, 'MANIFEST';
    open my $fh, '>>', $file or die "cannot open $file: $!";
    print $fh join "", map {"$_\n"} @{ expand_tree(@files) };
    close $fh;
}

sub dumper {
    require Data::Dumper;
    print STDERR Data::Dumper::Dumper(@_);
}

sub report {
    print STDERR "+++ $_[0]\n";
}

__END__
1;