Catalyst::Action::REST - Automated REST Method Dispatching

    sub foo :Local :ActionClass('REST') {
      ... do setup for HTTP method specific handlers ...
    }

    sub foo_GET {
      ... do something for GET requests ...
    }

    # alternatively use an Action
    sub foo_PUT : Action {
      ... do something for PUT requests ...
    }

   sub foo_not_implemented {
      ... handle not implemented methods ...
   }

package Catalyst::Action::REST;

use Moose;
use namespace::autoclean;

extends 'Catalyst::Action';
use Class::Inspector;
use Catalyst::Request::REST;
use Catalyst::Controller::REST;

BEGIN { require 5.008001; }

our $VERSION = '0.90';
$VERSION = eval $VERSION;

sub BUILDARGS {
    my $class  = shift;
    my $config = shift;
    Catalyst::Request::REST->_insert_self_into( $config->{class} );
    return $class->SUPER::BUILDARGS($config, @_);
}

sub dispatch {
    my $self = shift;
    my $c    = shift;

    my $rest_method = $self->name . "_" . uc( $c->request->method );

    return $self->_dispatch_rest_method( $c, $rest_method );
}

sub _dispatch_rest_method {
    my $self        = shift;
    my $c           = shift;
    my $rest_method = shift;

    my $controller = $c->component( $self->class );

    my ($code, $name);

    # Common case, for foo_GET etc
    if ( $code = $controller->action_for($rest_method) ) {
        $c->execute( $self->class, $self, @{ $c->req->args } ); # Execute normal 'foo' action.
        return $c->forward( $code,  $c->req->args ); # Forward to foo_GET if it's an action
    }
    elsif ($code = $controller->can($rest_method)) {
        # Execute normal action
        $c->execute( $self->class, $self, @{ $c->req->args } );
        $name = $rest_method; # Stash name and code to run 'foo_GET' like an action below.
    }

    # Generic handling for foo_OPTIONS
    if (!$code) {
        if ( $c->request->method eq "OPTIONS") {
            $name = $rest_method;
            $code = sub { $self->_return_options($self->name, @_) };
        }
        else {
            # Otherwise, not implemented.
            $name = $self->name . "_not_implemented";
            $code = $controller->can($name) # User method
                # Generic not implemented
                || sub { $self->_return_not_implemented($self->name, @_) };
        }
    }

    # localise stuff so we can dispatch the action 'as normal, but get
    # different stats shown, and different code run.
    local $self->{code} = $code;
    local $self->{reverse} = $name;

    $c->execute( $self->class, $self, @{ $c->req->args } );
}

sub _get_allowed_methods {
    my ( $self, $controller, $c, $name ) = @_;
    my $class = ref($controller) ? ref($controller) : $controller;
    my $methods = Class::Inspector->methods($class);
    return map { /^$name\_(.+)$/ } @$methods;
};

sub _return_options {
    my ( $self, $method_name, $controller, $c) = @_;
    my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
    $c->response->content_type('text/plain');
    $c->response->status(200);
    $c->response->header( 'Allow' => \@allowed );
}

sub _return_not_implemented {
    my ( $self, $method_name, $controller, $c ) = @_;

    my @allowed = $self->_get_allowed_methods($controller, $c, $method_name);
    $c->response->content_type('text/plain');
    $c->response->status(405);
    $c->response->header( 'Allow' => \@allowed );
    $c->response->body( "Method "
          . $c->request->method
          . " not implemented for "
          . $c->uri_for( $method_name ) );
}

__PACKAGE__->meta->make_immutable;

1;