Catalyst::Controller::CGIBin - Serve CGIs from root/cgi-bin

    package MyApp::Controller::Foo;

    use parent qw/Catalyst::Controller::CGIBin/;

    <Controller::Foo>
        cgi_root_path    cgi-bin
        cgi_dir          cgi-bin
        cgi_chain_root   /optional/private/path/to/Chained/root
        cgi_file_pattern *.cgi
        # or regex
        cgi_file_pattern /\.pl\z/
        <CGI>
            username_field username # used for REMOTE_USER env var
            pass_env PERL5LIB
            pass_env PATH
            pass_env /^MYAPP_/
        </CGI>
    </Controller::Foo>

    sub { system $path }

package Catalyst::Controller::CGIBin;

use Moose;
use Moose::Util::TypeConstraints;
use mro 'c3';

extends 'Catalyst::Controller::WrapCGI';

use File::Find::Rule ();
use File::Spec::Functions qw/splitdir abs2rel/;
use IPC::Open3;
use Symbol 'gensym';
use List::MoreUtils 'any';
use IO::File ();
use File::Temp 'tempfile';
use File::pushd;
use CGI::Compile;

use namespace::clean -except => 'meta';

our $VERSION = '0.033';

{ my $stringified = subtype as 'Str';
  coerce $stringified,
      from 'Object',
      via { "$_" };

  has cgi_root_path    => (is => 'ro', coerce => 1, isa => $stringified, default => 'cgi-bin' );
  has cgi_chain_root   => (is => 'ro', isa => 'Str');
  has cgi_dir          => (is => 'ro', coerce => 1, isa => $stringified, default => 'cgi-bin');
  has cgi_file_pattern => (is => 'rw', default => sub { ['*'] });

}

sub register_actions {
    my ($self, $app) = @_;

    my $cgi_bin;
    if( File::Spec->file_name_is_absolute($self->cgi_dir) ) {
        $cgi_bin = $self->cgi_dir;
    } elsif( File::Spec->file_name_is_absolute( $app->config->{root} ) ) {
        $cgi_bin = File::Spec->catdir( $app->config->{root}, $self->cgi_dir );
    } else {
        $cgi_bin = $app->path_to( $app->config->{root}, $self->cgi_dir);
    }

    my $namespace = $self->action_namespace($app);

    my $class = ref $self || $self;

    my $patterns = $self->cgi_file_pattern;
    $patterns = [ $patterns ] if not ref $patterns;
    for my $pat (@$patterns) {
        if ($pat =~ m{^/(.*)/\z}) {
            $pat = qr/$1/;
        }
    }
    $self->cgi_file_pattern($patterns);

    for my $file (File::Find::Rule->file->name(@$patterns)->in($cgi_bin)) {
        my $cgi_path = abs2rel($file, $cgi_bin);

        next if any { $_ eq '.svn' } splitdir $cgi_path;
        next if $cgi_path =~ /\.swp\z/;

        my $path        = join '/' => splitdir($cgi_path);
        my $action_name = $self->cgi_action($path);
        my $reverse     = $namespace ? "$namespace/$action_name" : $action_name;

        my $attrs = do {
            if (my $chain_root = $self->cgi_chain_root) {
                { Chained => [ $chain_root ], PathPart => [ $path ], Args => [] };
            }
            else {
                { Path => [ $self->cgi_path($path) ] };
            }
        };

        my ($cgi, $type);

        if ($self->is_perl_cgi($file)) { # syntax check passed
            $type = 'Perl';
            $cgi  = $self->wrap_perl_cgi($file, $action_name);
        } else {
            $type = 'Non-Perl';
            $cgi  = $self->wrap_nonperl_cgi($file, $action_name);
        }

        $app->log->info("Registering root/cgi-bin/$cgi_path as a $type CGI.")
            if $app->debug;

        my $code = sub {
            my ($controller, $context) = @_;
            $controller->cgi_to_response($context, $cgi)
        };

        my $action = $self->create_action(
            name       => $action_name,
            code       => $code,
            reverse    => $reverse,
            namespace  => $namespace,
            class      => $class,
            attributes => $attrs
        );

        $app->dispatcher->register($app, $action);
    }

    $self->next::method($app, @_);

# Tell Static::Simple to ignore cgi_dir
    if ($cgi_bin =~ /^\Q@{[ $app->path_to('root') ]}\E/) {
        my $rel = File::Spec->abs2rel($cgi_bin, $app->path_to('root'));

        if (!any { $_ eq $rel }
                @{ $app->config->{static}{ignore_dirs}||[] }) {
            push @{ $app->config->{static}{ignore_dirs} }, $rel;
        }
    }
}

sub cgi_action {
    my ($self, $cgi) = @_;

    my $action_name = 'CGI_' . $cgi;
    $action_name =~ s/([^A-Za-z0-9_])/sprintf("_%2x", unpack("C", $1))/eg;

    return $action_name;
}

sub cgi_path {
    my ($self, $cgi) = @_;

    my $root = $self->cgi_root_path;
    $root =~ s{/*$}{};
    return "$root/$cgi";
}

sub is_perl_cgi {
    my ($self, $cgi) = @_;

    if ($^O eq 'MSWin32') {
        # the fork code fails on Win32
        eval { $self->wrap_perl_cgi($cgi, '__DUMMY__') };
        my $success = $@ ? 0 : 1;
        require Class::Unload;
        Class::Unload->unload($self->cgi_package('__DUMMY__'));
        return $success;
    }

    my (undef, $tempfile) = tempfile;

    my $pid = fork;
    die "Cannot fork: $!" unless defined $pid;

    if ($pid) {
        waitpid $pid, 0;
        my $errors = IO::File->new($tempfile)->getline;
        unlink $tempfile;
        return $errors ? 0 : 1;
    }

    # child
    local *NULL;
    open NULL, '>', File::Spec->devnull;
    open STDOUT, '>&', \*NULL;
    open STDERR, '>&', \*NULL;
    close STDIN;

    eval { $self->wrap_perl_cgi($cgi, '__DUMMY__') };

    IO::File->new(">$tempfile")->print($@);

    exit;
}

sub wrap_perl_cgi {
    my ($self, $cgi, $action_name) = @_;

    return CGI::Compile->compile($cgi, $self->cgi_package($action_name));
}

sub cgi_package {
    my ($self, $action_name) = @_;

    return "Catalyst::Controller::CGIBin::_CGIs_::$action_name";
}

sub wrap_nonperl_cgi {
    my ($self, $cgi, $action_name) = @_;

    return sub {
        system $cgi;

        if ($? == -1) {
            die "failed to execute CGI '$cgi': $!";
        }
        elsif ($? & 127) {
            die sprintf "CGI '$cgi' died with signal %d, %s coredump",
                ($? & 127),  ($? & 128) ? 'with' : 'without';
        }
        else {
            my $exit_code = $? >> 8;

            return 0 if $exit_code == 0;

            die "CGI '$cgi' exited non-zero with: $exit_code";
        }
    };
}

__PACKAGE__->meta->make_immutable;

1; # End of Catalyst::Controller::CGIBin
# vim:et sw=4 sts=4 tw=0: