Catalyst::Example::Controller::InstantCRUD - Catalyst CRUD example Controller

    use base Catalyst::Example::Controller::InstantCRUD;

  

package Catalyst::Example::Controller::InstantCRUD;

use Moose;
BEGIN {
       extends 'Catalyst::Controller';
}

with 'Catalyst::Component::ContextClosure';

use Carp;
use Data::Dumper;
use Path::Class;

our $VERSION = '0.016';

has source_name => ( isa => 'Str', is => 'rw', lazy => 1, builder => 'build_source_name' );
sub build_source_name {
    my $self  = shift;
    my $class = ref $self;
    $class =~ /([^:]*)$/;
    return $1;
}

has form_class => ( isa => 'Str', is => 'rw', lazy => 1, builder => 'build_form_class' );
sub build_form_class {
    my $self  = shift;
    return ref( $self ) . '::' . $self->source_name . 'Form';
}

sub auto : Action {
    my ( $self, $c ) = @_;
    $c->stash->{additional_template_paths} = [ dir( $c->config->{root}, lc $self->source_name) . '', $c->config->{root} . ''];
}

sub model_item {
    my ( $self, $c, @pks ) = @_;
    my $rs = $self->model_resultset($c);
    my @pk_columns = $rs->result_source->primary_columns;
    my $data = {
        map { $pk_columns[$_] => $pks[$_] } 0..$#pk_columns
    };
    my $item = $rs->find($data, { key => 'primary' });
    return $item;
}

sub model_resultset {
    my ( $self, $c ) = @_;
    my $source     = $self->source_name;
    return $self->model_schema($c)->resultset($source);
}

sub model_schema {
    my ( $self, $c ) = @_;
    my $model_name = $c->config->{InstantCRUD}{model_name};
    return $c->model($model_name);
}

sub index : Private {
    my ( $self, $c ) = @_;
    $c->stash->{template} = lc( $self->source_name ) . '/list.tt';
    $c->forward('list');
}

sub destroy : Action {
    my ( $self, $c, @pks ) = @_;
    if ( $c->req->method eq 'POST' ) {
        $self->model_item( $c, @pks )->delete;
        $c->res->redirect(
            $c->uri_for( $self->action_for('list') )
        );
    }
    else {
        my $action_uri = $c->uri_for( $self->action_for('destroy'), @pks);
        $c->stash->{destroywidget} = <<END;
<form action="$action_uri" id="widget" method="post">
<fieldset class="widget_fieldset">
<input class="submit" id="widget_ok" name="ok" type="submit" value="Delete ?" />
</fieldset>
</form>
END
    }
}

sub build_form {
    my ( $self, $c, @pks ) = @_;
    my @ids;
    @ids = ( item_id => [ @pks ] ) if @pks;
    return $self->form_class->new( 
        schema => $self->model_schema($c), 
        params => $c->req->params, 
        @ids,
    );
}

sub edit : Action {
    my ( $self, $c, @pks ) = @_; 
    my $form = $self->build_form($c, @pks);
    my $item = $form->item;
    if( $c->req->method eq 'POST' && $form->process() ){
        $item = $form->item;
        $c->res->redirect( $c->uri_for( $self->action_for('view'), $item->id ) );
    }
    if( @pks ){
        $form->field( 'submit' )->value( 'Update' );
    }
    else{
        $form->field( 'submit' )->value( 'Create' );
    }

    $c->stash(
        form => $form,
        item => $item,
    );
}

sub view : Action {
    my ( $self, $c, @pks ) = @_;
    die "You need to pass an id" unless @pks;
    my $item = $self->model_item( $c, @pks );
    $c->stash->{item} = $item;
}

sub get_resultset {
    my ( $self, $c ) = @_;
    my $params = $c->request->params;
    my $order = $params->{'order'};
    $order .= ' DESC' if $params->{'o2'};
    my $join;
    if ( $order && $order =~ m/(\w+)\.\w+/ ) {
        $join = $1;
    }
    my $maxrows = $c->config->{InstantCRUD}{maxrows} || 10;
    my $page = $params->{'page'} || 1;
    return $self->model_resultset($c)->search(
        {},
        {
            page     => $page,
            $join ? ( join => $join ) : (),
            order_by => $order,
            rows     => $maxrows,
        }
    );
}

sub create_col_link {
    my ( $self, $c, $source ) = @_;
    my $origparams = $c->request->params;
    return $self->make_context_closure(sub {
        my ( $ctx, $column, $label ) = @_;
        my $addr;
        no warnings 'uninitialized';
        if ( $origparams->{'order'} eq $column && !$origparams->{'o2'} ) {
            $addr = $ctx->request->uri_with({ page => 1, order =>  $column, o2 => 'desc' });
        }else{
            $addr = $ctx->request->uri_with({ page => 1, order =>  $column, o2 => undef });
        }
        my $result = qq{<a href="$addr">$label</a>};
        if ( $origparams->{'order'} && $column eq $origparams->{'order'} ) {
            $result .= $origparams->{'o2'} ? "&darr;" : "&uarr;";
        }
        return $result;
    }, $c);
}

sub list : Action {
    my ( $self, $c ) = @_;
    my $result = $self->get_resultset($c);
    $c->stash->{pager}     = $result->pager;
    my $source  = $result->result_source;
    ($c->stash->{pri}) = $source->primary_columns;
    $c->stash->{order_by_column_link} = $self->create_col_link($c, $source);
    $c->stash->{result} = $result;
}



1;

__END__