Catalyst::Model::HTML::FormFu - FormFu In Your Model (Deprecated)

  # Install formfu elements
  # (See perldoc Catalyst::Helper::Model::HTML::FormFu)
  ./script/myapp_create.pl model YourModelName FormFu [dirname]

  # In your app
  MyApp->config(
    'Model::HTML::FormFu' => {
      cache_backend   => 'formfu', # optional
      config_dir      => '/path/to/basedir/', # optional
      contructor_args => { ... },  # optional
      stash_key       => 'form',   # optional
    }
  );

  # in your controller
  sub foo : Local
  {
     my ($self, $c) = @_;
     $c->model('FormFu')->load_form('path/to/file.yml');
  }

  *** WARNING ***
  This module has been deprecated.
  Please consider using Catalyst::Controller::HTML::FormFu instead.
  ***************

  MyApp->config(
    'Model::HTML::FormFu' => {
       stash_key => 'form'
    }
  );

  sub foo : Local {
    my($self, $c) = @_;
    my $form = $c->model('FormFu')->load_form('path/to/form.yml');
    if ($form->submitted_and_valid) {
       ...
    }
  }

  [% form %]

  - type: text
    value: __dynamic(method_name)__

  # config
  - type: select
    options: __dynamic(select_from_db)__

  # MyApp::Model::HTML::FormFu
  sub select_from_db {
    my ($self, $c) = @_;
    my @values = $c->model('DBIC')->resultset('SelectValues')->all;
    # munge @values so that it conforms to HTML::FormFu's spec
    ....

    return \@values;
  }

  MyApp->config(
    'Model::HTML::FormFu' => {
      config_dir => '/path/to/basedir'
    }
  )

  MyApp->config(
    'Model::HTML::FormFu' => {
      cache_backend => 'formfu'
    }
  )

# $Id: /mirror/perl/Catalyst-Model-HTML-FormFu/trunk/lib/Catalyst/Model/HTML/FormFu.pm 36884 2007-12-25T06:25:05.268411Z daisuke  $
#
# Copyright (c) 2007 Daisuke Maki <daisuke@endeworks.jp>

package Catalyst::Model::HTML::FormFu;
use strict;
use warnings;
use base qw(Catalyst::Model);
our $VERSION = '1.00001';
use Class::C3;
use Config::Any;
use Data::Visitor::Callback;
use HTML::FormFu;

BEGIN
{
    Class::C3::initialize();
}

__PACKAGE__->mk_accessors($_) for qw(context visitor config_dir constructor_args cache_backend stash_key _cache);

sub ACCEPT_CONTEXT
{
    my $self = shift;
    $self->context($_[0]);
    return $self;
}

sub load_form
{
    my $self   = shift;
    my $c      = eval { $_[0]->isa('Catalyst') } ? shift : $self->context;
    my $config = shift;

    my $method = 
        (eval { $config->isa('Path::Class::File') } || ! ref $config) ?
            '_load_from_file' :
            '_load_from_hash'
    ;
    my $form =  $self->$method($c, $config);

    # Actuall process the form
    $form->process( $c->request );
    if (my $key = $self->stash_key) {
        $c->stash->{$key} = $form;
    }
    return $form;
}

sub cache
{
    my ($self, $c) = @_;

    my $cache = $self->_cache;
    if (! $cache) {
        my $backend = $self->cache_backend;
        if ($c->can('cache') && $backend) {
            $cache = $c->cache( $backend );
            $self->_cache($cache);
        }
    }
    return $cache;
}

sub _load_from_file
{
    my ($self, $c, $file) = @_;

    if (! ref $file) {
        $file = Path::Class::File->new($file);
    }

    if (! $file->is_absolute) {
        # if this exists in the config...
        my $dir = $self->config_dir;
        $file = $dir ?
            Path::Class::Dir->new($dir)->file($file) :
            $c->path_to(qw(root formfu), $file)
        ;
    }

    # finally
    $file = $file->stringify;
    my $mtime = (stat($file))[9];

    my $cached_data;
    my $cache = $self->cache($c);
    if ($cache) {
        $cached_data = $cache->get($file);
        # If the cached data is older than the file, reload
        if ($cached_data) {
            if ($cached_data->{mtime} < $mtime) {
                $c->log->debug("HTML::FormFu config file $file has been modified since last load time. Throwing away cache and reloading") if $c->log->is_debug;
                undef $cached_data;
            } else {
                # No changes, return the cached form
                return $cached_data->{form};
            }
        }
    }

    my $loaded = Config::Any->load_files({ files => [$file], use_ext => 1 });
    my $config = $loaded->[0]->{$file} ||
        Catalyst::Exception->throw("Could not load form $file");
    $config    = $self->_filter_dynamic_values($c, $config);
    my $form      = $self->_construct_formfu($c, $config);
    $cache->set($file, { form => $form, mtime => $mtime }) if $cache;
    return $form;
}

sub _load_from_hash
{
    my ($self, $c, $config) = @_;

    my $form;
    my $cache = $self->_cache($c);
    my $key;
    if ($cache) {
        $key = do {
            require Data::Dumper;
            require Digest::MD5;
            local $Data::Dumper::Indent   = 1;
            local $Data::Dumper::Sortkeys = 1;
            local $Data::Dumper::Terse    = 1;

            Digest::MD5::md5_hex( Data::Dumper::Dumper($config) );
        };
        $form = $cache->get($key);
    }

    if (! $form) {
        $config = $self->_filter_dynamic_values($c, $config);
        $form   = $self->_construct_formfu($c, $config);

        $cache->set($key, $form) if $cache;
    }

    return $form;
}

sub _construct_formfu
{
    my ($self, $c, $config) = @_;

    my $constructor_args = $self->constructor_args || {};
    $constructor_args->{query_type} = 'Catalyst';
    $constructor_args->{tt_args} ||= {};
    $constructor_args->{tt_args}->{INCLUDE_PATH} ||= $c->path_to('root', 'formfu')->stringify;

    my $form = HTML::FormFu->new($constructor_args);
    $form->populate($config);

    return $form;
}

sub _filter_dynamic_values
{
    my ($self, $c, $config) = @_;

    my $visitor = $self->visitor;
    if (! $visitor) {
        $visitor = Data::Visitor::Callback->new(
            plain_value => sub {
                my ($visitor, $value) = @_;
                if ($value !~ /^__dynamic\(([^\)]+)\)__$/) {
                    return $value;
                }

                my $method = $1;
                return $self->$method($self->context);
            }
        );
        $self->visitor($visitor);
    }

    return $visitor->visit($config);
}

1;

__END__