Catalyst::DispatchType::Index - Index DispatchType

Catalyst-Runtime documentation Contained in the Catalyst-Runtime distribution.

Index

Code Index:

NAME

Top

Catalyst::DispatchType::Index - Index DispatchType

SYNOPSIS

Top

See Catalyst::DispatchType.

DESCRIPTION

Top

Dispatch type managing behaviour for index pages. For more information on dispatch types, see:

* Catalyst::Manual::Intro for how they affect application authors
* Catalyst::DispatchType for implementation information.

METHODS

Top

$self->match( $c, $path )

Check if there's an index action for a given path, and set it up to use it if there is; only matches a full URI - if $c->req->args is already set this DispatchType is guaranteed not to match.

$self->register( $c, $action )

Register an action with this DispatchType.

$self->uri_for_action( $action, $captures )

get a URI part for an action; always returns undef is $captures is set since index actions don't have captures

AUTHORS

Top

Catalyst Contributors, see Catalyst.pm

COPYRIGHT

Top

This library is free software. You can redistribute it and/or modify it under the same terms as Perl itself.

Catalyst-Runtime documentation Contained in the Catalyst-Runtime distribution. 
package Catalyst::DispatchType::Index;

use Moose;
extends 'Catalyst::DispatchType';
use namespace::clean -except => 'meta';


has _actions => (
    is => 'rw', isa => 'HashRef', default => sub { +{} }
);


sub match {
    my ( $self, $c, $path ) = @_;
    return if @{ $c->req->args };
    my $result = $c->get_action( 'index', $path );

    return 0 unless $result && exists $self->_actions->{ $result->reverse };

    if ($result && $result->match($c)) {
        $c->action($result);
        $c->namespace( $result->namespace );
        $c->req->action('index');
        $c->req->match( $c->req->path );
        return 1;
    }
    return 0;
}


sub register {
    my ( $self, $c, $action ) = @_;

    $self->_actions->{ $action->reverse } = $action if $action->name eq 'index';

    return 1;
}


sub uri_for_action {
    my ( $self, $action, $captures ) = @_;

    return undef if @$captures;

    return undef unless exists $self->_actions->{ $action->reverse };

    return "/".$action->namespace;
}

sub _is_low_precedence { 1 }


__PACKAGE__->meta->make_immutable;

1;