Catalyst::Response - stores output responding to the current client request

Catalyst-Runtime documentation Contained in the Catalyst-Runtime distribution.

Index

Code Index:

NAME

Top

Catalyst::Response - stores output responding to the current client request

SYNOPSIS

Top

    $res = $c->response;
    $res->body;
    $res->code;
    $res->content_encoding;
    $res->content_length;
    $res->content_type;
    $res->cookies;
    $res->header;
    $res->headers;
    $res->output;
    $res->redirect;
    $res->status;
    $res->write;

DESCRIPTION

Top

This is the Catalyst Response class, which provides methods for responding to the current client request. The appropriate Catalyst::Engine for your environment will turn the Catalyst::Response into a HTTP Response and return it to the client.

METHODS

Top

$res->body( $text | $fh | $iohandle_object )

    $c->response->body('Catalyst rocks!');

Sets or returns the output (text or binary data). If you are returning a large body, you might want to use a IO::Handle type of object (Something that implements the read method in the same fashion), or a filehandle GLOB. Catalyst will write it piece by piece into the response.

$res->has_body

Predicate which returns true when a body has been set.

$res->code

Alias for $res->status.

$res->content_encoding

Shortcut for $res->headers->content_encoding.

$res->content_length

Shortcut for $res->headers->content_length.

$res->content_type

Shortcut for $res->headers->content_type.

This value is typically set by your view or plugin. For example, Catalyst::Plugin::Static::Simple will guess the mime type based on the file it found, while Catalyst::View::TT defaults to text/html.

$res->cookies

Returns a reference to a hash containing cookies to be set. The keys of the hash are the cookies' names, and their corresponding values are hash references used to construct a CGI::Simple::Cookie object.

    $c->response->cookies->{foo} = { value => '123' };

The keys of the hash reference on the right correspond to the CGI::Simple::Cookie parameters of the same name, except they are used without a leading dash. Possible parameters are:

value
expires
domain
path
secure
httponly

$res->header

Shortcut for $res->headers->header.

$res->headers

Returns an HTTP::Headers object, which can be used to set headers.

    $c->response->headers->header( 'X-Catalyst' => $Catalyst::VERSION );

$res->output

Alias for $res->body.

$res->redirect( $url, $status )

Causes the response to redirect to the specified URL. The default status is 302.

    $c->response->redirect( 'http://slashdot.org' );
    $c->response->redirect( 'http://slashdot.org', 307 );

This is a convenience method that sets the Location header to the redirect destination, and then sets the response status. You will want to return or $c->detach() to interrupt the normal processing flow if you want the redirect to occur straight away.

$res->location

Sets or returns the HTTP 'Location'.

$res->status

Sets or returns the HTTP status.

    $c->response->status(404);

$res->code is an alias for this, to match HTTP::Response->code.

$res->write( $data )

Writes $data to the output stream.

meta

Provided by Moose

$res->print( @data )

Prints @data to the output stream, separated by $,. This lets you pass the response object to functions that want to write to an IO::Handle.

AUTHORS

Top

Catalyst Contributors, see Catalyst.pm

COPYRIGHT

Top

This library is free software. You can redistribute it and/or modify it under the same terms as Perl itself.

Catalyst-Runtime documentation Contained in the Catalyst-Runtime distribution. 
package Catalyst::Response;

use Moose;
use HTTP::Headers;

with 'MooseX::Emulate::Class::Accessor::Fast';

has cookies   => (is => 'rw', default => sub { {} });
has body      => (is => 'rw', default => undef);
sub has_body { defined($_[0]->body) }

has location  => (is => 'rw');
has status    => (is => 'rw', default => 200);
has finalized_headers => (is => 'rw', default => 0);
has headers   => (
  is      => 'rw',
  handles => [qw(content_encoding content_length content_type header)],
  default => sub { HTTP::Headers->new() },
  required => 1,
  lazy => 1,
);
has _context => (
  is => 'rw',
  weak_ref => 1,
  handles => ['write'],
  clearer => '_clear_context',
);

sub output { shift->body(@_) }

sub code   { shift->status(@_) }

no Moose;


sub redirect {
    my $self = shift;

    if (@_) {
        my $location = shift;
        my $status   = shift || 302;

        $self->location($location);
        $self->status($status);
    }

    return $self->location;
}


sub print {
    my $self = shift;
    my $data = shift;

    defined $self->write($data) or return;

    for (@_) {
        defined $self->write($,) or return;
        defined $self->write($_) or return;
    }

    return 1;
}


__PACKAGE__->meta->make_immutable;

1;