Class::Accessor::Lvalue::Fast - create simplified Lvalue accessors

 package Foo;
 use base qw( Class::Accessor::Lvalue::Fast );
 __PACKAGE__->mk_accessors(qw( bar ))

 my $foo = Foo->new;
 $foo->bar = 42;
 print $foo->bar; # prints 42

use strict;
package Class::Accessor::Lvalue::Fast;
use base qw(Class::Accessor::Fast);
use Want;

sub make_accessor {
    my ($class, $field) = @_;

    return sub :lvalue {
        my $self = shift;
        $self->{$field};
    };
}

sub make_ro_accessor {
    my($class, $field) = @_;

    return sub :lvalue {
        my $self = shift;
        if (want 'LVALUE') {
            my $caller = caller;
            require Carp;
            Carp::croak("'$caller' cannot alter the value of '$field' on ".
                          "objects of class '$class'");
        }
        return $self->{$field};
    };
}

sub make_wo_accessor {
    my($class, $field) = @_;

    return sub :lvalue {
        my $self = shift;
        unless (want 'LVALUE') {
            my $caller = caller;
            require Carp;
            Carp::croak("'$caller' cannot access the value of '$field' on ".
                          "objects of class '$class'");
        }
        $self->{$field};
    };
}

1;
__END__