Class::Value::Contact::Address::Country - Contact-related value objects

  Marcel Gruenauer <marcel@cpan.org>

use 5.008;
use strict;
use warnings;

package Class::Value::Contact::Address::Country;
our $VERSION = '1.100840';
# ABSTRACT: Contact-related value objects
use Error::Hierarchy::Util 'assert_defined';
use parent 'Class::Value::Contact::Address';

# Class method:
#
# Takes a potential country name which could be an alias and returns the
# normal country name for that country (e.g., 'Oesterreich' and 'Austria'
# both map to 'Austria') If the name is already the normal name, it isn't
# changed and returned. If the name given isn't a country name (or an
# alias), a false value is returned.
sub normalize_value {
    my ($self, $value) = @_;
    return unless $value;
    $self->get_short_country_name($value);
}

# get_normal_country_name() can be called as a class method with an argument,
# or as an object method without an argument (in which case it will act on the
# object's value).
sub get_normal_country_name {
    my ($self, $country) = @_;
    our %cache;
    $country = $self->value unless defined $country;
    $cache{normal_country_name}{$country} =
      $self->_get_normal_country_name($country)
      unless defined $cache{normal_country_name}{$country};
    $cache{normal_country_name}{$country};
}

sub _get_normal_country_name {
    my ($self, $country) = @_;
    $country;    # no normalizations defined
}

# get_short_country_name() can be called as a class method with an argument,
# or as an object method without an argument (in which case it will act on the
# object's value).
sub get_short_country_name {
    my ($self, $country) = @_;
    our %cache;
    $country = $self->value unless defined $country;
    $cache{short_country_name}{$country} =
      $self->_get_short_country_name($country)
      unless defined $cache{short_country_name}{$country};
    $cache{short_country_name}{$country};
}

sub _get_short_country_name {
    my ($self, $country) = @_;
    undef;    # no short country names defined
}

sub send_notify_value_normalized {
    my ($self, $value, $normalized) = @_;
    my $class = 'Class::Value::Contact::Exception::ReplaceAliasCountry';
    $self->exception_container->record(
        $class,
        original    => $value,
        replacement => $normalized,
    );
}

sub send_notify_value_invalid {
    my ($self, $value) = @_;
    local $Error::Depth = $Error::Depth + 2;
    $self->exception_container->record(
        'Class::Value::Contact::Exception::InvalidCountry',
        country => $value,);
}
1;


__END__