Config::Apt::SourceEntry - Manipulate apt source entries

Config-Apt-Sources documentation Contained in the Config-Apt-Sources distribution.

Index

Code Index:

NAME

Top

Config::Apt::SourceEntry - Manipulate apt source entries

VERSION

Top

Version 0.10

SYNOPSIS

Top

    use Config::Apt::SourceEntry;

    my $src = new Config::Apt::SourceEntry;
    $src->from_string("deb http://ftp.us.debian.org/debian/ unstable main");
    ...
    my $src = new Config::Apt::SourceEntry("deb http://ftp.us.debian.org/debian/ unstable main non-free");
    $src->set_uri("http://apt-proxy:9999/");
    print $src->to_string();

FUNCTIONS

Top

new

The Config::Apt::SourceEntry constructor has one optional string argument. If the optional argument is given, it will be parsed as an apt source.

to_string

Returns the string representation of the apt source. Takes no arguments.

    print $src->to_string();

from_string

Parses the given string argument as an apt source.

    $src->from_string("deb http://ftp.us.debian.org/debian/ unstable main");

Returns undef on error, otherwise 1.

get_type, get_uri, get_dist, get_components

Returns the type, uri, distribution (strings), or components (array of strings)

set_type, set_uri, set_dist, set_components

Sets the type, uri, distribution (strings), or components (array of strings)

AUTHOR

Top

Ian Kilgore, <iank at cpan.org>

BUGS

Top

Please report any bugs or feature requests to bug-config-apt-source at rt.cpan.org, or through the web interface at http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Config-Apt-Source. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

SUPPORT

Top

You can find documentation for this module with the perldoc command.

    perldoc Config::Apt::Source

You can also look for information at:

* AnnoCPAN: Annotated CPAN documentation

http://annocpan.org/dist/Config-Apt-Source

* CPAN Ratings

http://cpanratings.perl.org/d/Config-Apt-Source

* RT: CPAN's request tracker

http://rt.cpan.org/NoAuth/Bugs.html?Dist=Config-Apt-Source

* Search CPAN

http://search.cpan.org/dist/Config-Apt-Source

COPYRIGHT & LICENSE

Top

Copyright 2007 Ian Kilgore, all rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

Config-Apt-Sources documentation Contained in the Config-Apt-Sources distribution. 
package Config::Apt::SourceEntry;

use warnings;
use strict;


our $VERSION = '0.10';
use Carp;


sub new {
  my ($class_name) = @_;
  my ($self) = { 'type' => "",
                 'uri'  => "",
                 'dist' => "",
                 'components' => [ ],
               };

  bless($self, $class_name);
  if (@_ > 1) {
    if (!defined(from_string($self,$_[1]))) { $self = undef };
  }
  return $self;

}


sub to_string {
  my $self = shift;
  local $"=' ';
  my $ret = $self->{'type'} . " " . $self->{'uri'} . " " . $self->{'dist'};
  if (@{$self->{'components'}} > 0) {
    $ret .= " " . "@{ $self->{'components'} }";
  }
  return $ret;
}


sub from_string {
  my ($self,$str) = @_;
  # trim whitespace
  $str =~ s/^\s+//;
  $str =~ s/\s+$//;
  $str =~ s/\s+/ /g;

  # trim comments
  $str =~ s/#.*$//g;

  my @source = split / /,$str;
  unless (@source >= 3) {
    carp "Invalid source";
    return undef;
  }
  $self->{'type'} = shift @source;
  $self->{'uri'}  = shift @source;
  $self->{'dist'} = shift @source;
  $self->{'components'} = [ @source ];
  return 1;
}


sub get_type { my $self=shift;return $self->{'type'};   }
sub get_uri  { my $self=shift;return $self->{'uri'}; }
sub get_dist { my $self=shift;return $self->{'dist'};   }
sub get_components { my $self=shift;return @{ $self->{'components'} };}


sub set_type { my $self=shift;$self->{'type'} = shift; }
sub set_uri  { my $self=shift;$self->{'uri'}  = shift; }
sub set_dist { my $self=shift;$self->{'dist'} = shift; }
sub set_components { my $self=shift;$self->{'components'} = [ @_ ]; }


1; # End of Config::Apt::Source