Convert::Age - convert integer seconds into a "compact" form and back.

Convert-Age documentation Contained in the Convert-Age distribution.

Index

Code Index:

NAME

Top

Convert::Age - convert integer seconds into a "compact" form and back.

VERSION

Top

Version 0.04

SYNOPSIS

Top

    use Convert::Age;

    my $c = Convert::Age::encode(189988007); # 6y7d10h26m47s
    my $d = Convert::Age::decode('5h37m5s'); # 20225

    # or export functions

    use Convert::Age qw(encode_age decode_age);

    my $c = encode_age(20225); # 5h37m5s
    my $d = decode_age('5h37m5s'); # 5h37m5s

EXPORT

Top

encode_age

synonym for Convert::Age::encode()

decode_age

synonym for Convert::Age::decode()

NOTE

Top

The methods in this module are suitable for some kinds of logging and input/output conversions. It achieves the conversion through simple remainder arithmetic and the length of a year as 365.2425 days.

FUNCTIONS

Top

encode

convert seconds into a "readable" format 344 => 5m44s

encode_age

synonym for encode that can be exported

decode

convert the "readable" format into seconds

decode_age

synonym for encode that can be exported

AUTHOR

Top

Chris Fedde, <cfedde at cpan.org>

BUGS

Top

Please report any bugs or feature requests to bug-convert-age at rt.cpan.org, or through the web interface at http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Convert-Age. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

SUPPORT

Top

You can find documentation for this module with the perldoc command.

    perldoc Convert::Age

You can also look for information at:

* AnnoCPAN: Annotated CPAN documentation

http://annocpan.org/dist/Convert-Age

* CPAN Ratings

http://cpanratings.perl.org/d/Convert-Age

* RT: CPAN's request tracker

http://rt.cpan.org/NoAuth/Bugs.html?Dist=Convert-Age

* Search CPAN

http://search.cpan.org/dist/Convert-Age

ACKNOWLEDGEMENTS

Top

COPYRIGHT & LICENSE

Top

Copyright 2007 Chris Fedde, all rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

Convert-Age documentation Contained in the Convert-Age distribution. 
package Convert::Age;

use warnings;
use strict;


our $VERSION = '0.04';



use Exporter 'import';
our @EXPORT_OK = qw(encode_age decode_age);


my %convert = (
    y => 365.2425 * 3600 * 24,
    d => 3600 * 24,
    h => 3600,
    m => 60,
    s => 1,
);

sub encode {
    my $age = shift;

    my $out = "";

    my %tag = reverse %convert;

    # largest first
    for my $k (reverse sort {$a <=> $b} keys %tag) {
        next unless ($age >= $k);
        next if (int ($age / $k) == 0);

        $out .= int ($age / $k). $tag{$k};
        $age = $age % $k;
    }

    return $out;
}


sub encode_age {
    goto &encode;
}


sub decode {
    my $age = shift;

    return $age if ($age =~ /^\d+$/);

    my $seconds = 0;
    my $p = join "", keys %convert;
    my @l = split /([$p])/, $age;

    while (my ($c, $s) = splice(@l, 0, 2)) {
        $seconds += $c * $convert{$s};
    }

    return $seconds;
}


sub decode_age {
    goto &decode;
}


1; # End of Convert::Age