Digest::MultiHash - XOR based, variable width multiplexing of hashes (a

Crypt-Util documentation Contained in the Crypt-Util distribution.

Index

Code Index:

NAME

Top

Digest::MultiHash - XOR based, variable width multiplexing of hashes (a generalized Digest::SV1).

SYNOPSIS

Top

	use Digest::MultiHash;

	my $d = Digest::Multihash->new(
		width => 16, # bytes
		hashs => ["SHA-512", "Whirlpool"], # see below for arbitrary arguments
	);

	$d->add($data);

	print $d->hexdigest;

DESCRIPTION

Top

This class inherits from Digest::base, and provides generalized digest multiplexing.

It will multiplex all calls to add to all of it's sub digest objects. Likewise, when the final digest is extracted the digests will be extracted and then XOR'd over eachother according to width.

width will default to the width of the first hash if unspecified.

hashes defaults to SHA-1 for compatibility reasons.

This module is useful for generating keys from passphrases, by supplying the desired width and simply making sure there is enough data from the combined hashes.

METHODS

Top

See Digest for the complete API. This module inherits from Digest::base.

new

This methods accepts a hash reference or an even sized list of parameters named according to the methods.

add
digest

Compute the hash by calling digest on all of the subhashes, splitting the result up into width sized chunk, and then XORing these together.

If the result is not aligned on width the result will not be truncated. The shorter string will still be XOR'd with the hash, even if this only affects part of the result.

If there are not at least width bytes of data in the output of the combined hashes an error is thrown.

clone

Clones the hash.

hashes

Get the array of hashes to use. Array values in this will be dereferenced before the call to new in Digest to allow passing of arbitrary arguments. Blessed objects (of any class) will be used verbatim.

The list of hashes cannot be changed after construction.

width

Get/set the byte-width to use.

SEE ALSO

Top

Digest, Digest::SV1, Digest::SHA1

Crypt-Util documentation Contained in the Crypt-Util distribution. 
#!/usr/bin/perl

package Digest::MultiHash;
use Moose;

extends our @ISA, qw(Digest::base);

use Carp qw/croak/;

use Digest;
use Digest::MoreFallbacks;
use Scalar::Util qw/blessed/;

use namespace::clean -except => [qw(meta)];

has width => (
	isa => "Int",
	is  => "rw",
);

has hashes => (
	isa => "ArrayRef",
	is  => "ro",
	required => 1,
	default  => sub { [qw(SHA-1)] },
);

has _digest_objects => (
	isa => "ArrayRef",
	is  => "ro",
	lazy_build => 1,
);

sub BUILD {
	shift->_digest_objects; # force building
}

sub _call {
	my ( $self, $method, @args ) = @_;
	map { $_->$method( @args ) } @{ $self->_digest_objects };
}

sub _build__digest_objects {
	my $self = shift;

	my @digests = map {
		blessed($_)
			? $_
			: Digest->new(
				((ref($_)||'') eq "ARRAY")
					? @$_
					: $_
			)
	} @{ $self->hashes };

	die "No digest module specified" unless @digests;

	return \@digests;
}

# MooseX::Clone
sub clone {
	my $self = shift;

	$self->new(
		width  => $self->width,
		hashes => $self->hashes,
		_digest_objects => [ $self->_call("clone") ],
	);
}

sub add {
	my ( $self, @args ) = @_;
	$self->_call("add", @args);
}

sub digest {
	my $self = shift;

	my @digests = $self->_call("digest");
	
	my $width = $self->width || length($digests[0]);

	my $concat = join "", @digests;
	
	die "Chosen hashes are insufficient for desired width" if length($concat) < $width;

	my ( $buf, @pieces ) = unpack "(a$width)*", $concat;

	$buf ^= $_ for @pieces;

	return $buf;
}

__PACKAGE__;

__END__