DBIx::Class::Helpers::Util - Helper utilities for DBIx::Class components

DBIx-Class-Helpers documentation Contained in the DBIx-Class-Helpers distribution.

Index

Code Index:

NAME

Top

DBIx::Class::Helpers::Util - Helper utilities for DBIx::Class components

VERSION

Top

version 2.007000

SYNOPSIS

Top

 my ($namespace, $class) = get_namespace_parts('MyApp:Schema::Person');
 is $namespace, 'MyApp::Schema';
 is $class, 'Person';

 if (is_load_namespaces('MyApp::Schema::Result::Person')) {
   print 'correctly structured project';
 }

 if (is_not_load_namespaces('MyApp::Schema::Person')) {
   print 'incorrectly structured project';
 }

 if (assert_similar_namespaces('MyApp::Schema::Person', 'FooApp::Schema::People')) {
   print 'both projects are structured similarly';
 }

 if (assert_similar_namespaces('MyApp::Schema::Result::Person', 'FooApp::Schema::Result::People')) {
   print 'both projects are structured similarly';
 }

DESCRIPTION

Top

A collection of various helper utilities for DBIx::Class stuff. Probably only useful for components.

METHODS

Top

get_namespace_parts

Returns the namespace and class name of a package. See SYNOPSIS for example.

is_load_namespaces

Returns true if a package is structured in a way that would work for load_namespaces. See SYNOPSIS for example.

is_not_load_namespaces

Returns true if a package is structured in a way that would not work for load_namespaces. See SYNOPSIS for example.

assert_similar_namespaces

Dies if both packages are structured in the same way. The same means both are load_namespaces or both are not. See SYNOPSIS for example.

AUTHOR

Top

Arthur Axel "fREW" Schmidt <frioux+cpan@gmail.com>

COPYRIGHT AND LICENSE

Top

This software is copyright (c) 2011 by Arthur Axel "fREW" Schmidt.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

DBIx-Class-Helpers documentation Contained in the DBIx-Class-Helpers distribution. 
package DBIx::Class::Helpers::Util;
BEGIN {
  $DBIx::Class::Helpers::Util::VERSION = '2.007000';
}

use strict;
use warnings;

# ABSTRACT: Helper utilities for DBIx::Class components

use Sub::Exporter -setup => {
    exports => [
      qw(
         get_namespace_parts is_load_namespaces is_not_load_namespaces
         assert_similar_namespaces
      ),
    ],
  };

sub get_namespace_parts {
   my $package = shift;

   if ($package =~ m/(^[\w:]+::Result)::([\w:]+)$/) {
      return ($1, $2);
   } else {
      die "$package doesn't look like ".'$namespace::Result::$resultclass';
   }
}

sub is_load_namespaces {
   my $namespace = shift;
   $namespace =~ /^[\w:]+::Result::[\w]+$/;
}

sub is_not_load_namespaces {
   my $namespace = shift;
      $namespace =~ /^([\w:]+)::[\w]+$/ and
      $1           !~ /::Result/;
}

sub assert_similar_namespaces {
   my $ns1 = shift;
   my $ns2 = shift;

   die "Namespaces $ns1 and $ns2 are dissimilar"
      unless is_load_namespaces($ns1) and is_load_namespaces($ns2) or
             is_not_load_namespaces($ns1) and is_not_load_namespaces($ns2);
}

1;





__END__