DBIx::Class::ResultSetColumn - helpful methods for messing

  DBIx::Class::ResultSetColumn - helpful methods for messing
  with a single column of the resultset

  $rs = $schema->resultset('CD')->search({ artist => 'Tool' });
  $rs_column = $rs->get_column('year');
  $max_year = $rs_column->max; #returns latest year

  my $obj = DBIx::Class::ResultSetColumn->new($rs, $column);

  my $first_year = $year_col->min();

  my $rs = $year_col->min_rs();

  my $last_year = $year_col->max();

  my $rs = $year_col->max_rs();

  my $total = $prices_col->sum();

  my $rs = $year_col->sum_rs();

  $rs = $schema->resultset("CD")->search({});
  $length = $rs->get_column('title')->func('LENGTH');

  SELECT LENGTH( title ) FROM cd me

package DBIx::Class::ResultSetColumn;

use strict;
use warnings;

use base 'DBIx::Class';
use DBIx::Class::Carp;
use DBIx::Class::Exception;

# not importing first() as it will clash with our own method
use List::Util ();

sub new {
  my ($class, $rs, $column) = @_;
  $class = ref $class if ref $class;

  $rs->throw_exception('column must be supplied') unless $column;

  my $orig_attrs = $rs->_resolved_attrs;
  my $alias = $rs->current_source_alias;

  # If $column can be found in the 'as' list of the parent resultset, use the
  # corresponding element of its 'select' list (to keep any custom column
  # definition set up with 'select' or '+select' attrs), otherwise use $column
  # (to create a new column definition on-the-fly).
  my $as_list = $orig_attrs->{as} || [];
  my $select_list = $orig_attrs->{select} || [];
  my $as_index = List::Util::first { ($as_list->[$_] || "") eq $column } 0..$#$as_list;
  my $select = defined $as_index ? $select_list->[$as_index] : $column;

  my $new_parent_rs;
  # analyze the order_by, and see if it is done over a function/nonexistentcolumn
  # if this is the case we will need to wrap a subquery since the result of RSC
  # *must* be a single column select
  my %collist = map 
    { $_ => 1, ($_ =~ /\./) ? () : ( "$alias.$_" => 1 ) }
    ($rs->result_source->columns, $column)
  ;
  if (
    scalar grep
      { ! $collist{$_->[0]} }
      ( $rs->result_source->schema->storage->_extract_order_criteria ($orig_attrs->{order_by} ) ) 
  ) {
    # nuke the prefetch before collapsing to sql
    my $subq_rs = $rs->search;
    $subq_rs->{attrs}{join} = $subq_rs->_merge_joinpref_attr( $subq_rs->{attrs}{join}, delete $subq_rs->{attrs}{prefetch} );
    $new_parent_rs = $subq_rs->as_subselect_rs;
  }

  $new_parent_rs ||= $rs->search_rs;
  my $new_attrs = $new_parent_rs->{attrs} ||= {};

  # prefetch causes additional columns to be fetched, but we can not just make a new
  # rs via the _resolved_attrs trick - we need to retain the separation between
  # +select/+as and select/as. At the same time we want to preserve any joins that the
  # prefetch would otherwise generate.
  $new_attrs->{join} = $rs->_merge_joinpref_attr( $new_attrs->{join}, delete $new_attrs->{prefetch} );

  # {collapse} would mean a has_many join was injected, which in turn means
  # we need to group *IF WE CAN* (only if the column in question is unique)
  if (!$orig_attrs->{group_by} && keys %{$orig_attrs->{collapse}}) {

    # scan for a constraint that would contain our column only - that'd be proof
    # enough it is unique
    my $constraints = { $rs->result_source->unique_constraints };
    for my $constraint_columns ( values %$constraints ) {

      next unless @$constraint_columns == 1;

      my $col = $constraint_columns->[0];
      my $fqcol = join ('.', $new_attrs->{alias}, $col);

      if ($col eq $select or $fqcol eq $select) {
        $new_attrs->{group_by} = [ $select ];
        delete $new_attrs->{distinct}; # it is ignored when group_by is present
        last;
      }
    }

    if (!$new_attrs->{group_by}) {
      carp (
          "Attempting to retrieve non-unique column '$column' on a resultset containing "
        . 'one-to-many joins will return duplicate results.'
      );
    }
  }

  my $new = bless { _select => $select, _as => $column, _parent_resultset => $new_parent_rs }, $class;
  return $new;
}

sub as_query { return shift->_resultset->as_query(@_) }

sub next {
  my $self = shift;

  # using cursor so we don't inflate anything
  my ($row) = $self->_resultset->cursor->next;

  return $row;
}

sub all {
  my $self = shift;

  # using cursor so we don't inflate anything
  return map { $_->[0] } $self->_resultset->cursor->all;
}

sub reset {
  my $self = shift;
  $self->_resultset->cursor->reset;
  return $self;
}

sub first {
  my $self = shift;

  # using cursor so we don't inflate anything
  $self->_resultset->cursor->reset;
  my ($row) = $self->_resultset->cursor->next;

  return $row;
}

sub single {
  my $self = shift;

  my $attrs = $self->_resultset->_resolved_attrs;
  my ($row) = $self->_resultset->result_source->storage->select_single(
    $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
  );

  return $row;
}

sub min {
  return shift->func('MIN');
}

sub min_rs { return shift->func_rs('MIN') }

sub max {
  return shift->func('MAX');
}

sub max_rs { return shift->func_rs('MAX') }

sub sum {
  return shift->func('SUM');
}

sub sum_rs { return shift->func_rs('SUM') }

sub func {
  my ($self,$function) = @_;
  my $cursor = $self->func_rs($function)->cursor;

  if( wantarray ) {
    return map { $_->[ 0 ] } $cursor->all;
  }

  return ( $cursor->next )[ 0 ];
}

sub func_rs {
  my ($self,$function) = @_;
  return $self->{_parent_resultset}->search(
    undef, {
      select => {$function => $self->{_select}},
      as => [$self->{_as}],
    },
  );
}

sub throw_exception {
  my $self=shift;

  if (ref $self && $self->{_parent_resultset}) {
    $self->{_parent_resultset}->throw_exception(@_);
  }
  else {
    DBIx::Class::Exception->throw(@_);
  }
}

# _resultset
#
# Arguments: none
#
# Return Value: $resultset
#
#  $year_col->_resultset->next
#
# Returns the underlying resultset. Creates it from the parent resultset if
# necessary.
#
sub _resultset {
  my $self = shift;

  return $self->{_resultset} ||= $self->{_parent_resultset}->search(undef,
    {
      select => [$self->{_select}],
      as => [$self->{_as}]
    }
  );
}

1;