DVD::Read::Title - Fetch information from DVD video.

  use DVD::Read::Title;
  my $title = DVD::Read::Title->new('/dev/cdrom', 1);
  print $title->video_format_txt . "\n";

package DVD::Read::Title;

use 5.010000;
use strict;
use warnings;

use DVD::Read;
use DVD::Read::Dvd::Ifo::Vts;
use DVD::Read::Dvd::File;
use AutoLoader;
use vars qw($AUTOLOAD);
use Carp;

our $VERSION = '0.04';

sub AUTOLOAD {
    my ($self, @args) = @_;
    my $sub = $AUTOLOAD;
    $sub =~ s/.*:://;
    if (exists(${DVD::Read::Dvd::Ifo::Vts::}{"vts_$sub"})) {
        $sub = "vts_$sub";
        return $self->_vts->$sub(@args);
    } elsif (exists(${DVD::Read::Dvd::Ifo::Vts::}{$sub}) && $sub =~ /^chapter_/) {
        my ($chapter) = (@args);
        $self->_vts->$sub(
            $self->_vmg->title_ttn($self->{titleid}),
            $chapter,
        );
    } else {
        croak("No function DVD::Read::Title::$sub");
    }
}

sub DESTROY {}

sub new {
    my ($class, $dvd, $title) = @_;

    my $dvdobj = ref $dvd
        ? $dvd
        : DVD::Read->new($dvd);

    my $self = bless({
        titleid => $title,
        dvd => $dvdobj,
        vts => undef,
    }, $class);

    $self->_vts or return;

    $dvdobj->{vts}[$title] = $self;
}

sub _dvd {
    my ($self) = @_;
    return $self->{dvd}
}

sub _vmg {
    my ($self) = @_;
    return $self->_dvd->_vmg;
}

sub _vts {
    my ($self) = @_;
    $self->_vmg or return;
    my $nr = $self->title_nr or return;
    return $self->{vts} ||=
        DVD::Read::Dvd::Ifo::Vts->new($self->_dvd->{dvd}, $nr);
}

sub length {
    my ($self) = @_;
    $self->_vmg or return;
    $self->_vts->title_length(
        $self->_vmg->title_ttn($self->{titleid}),
    );
}

sub chapters_count {
    my ($self) = @_;
    $self->_vmg or return;
    $self->_vmg->title_chapters_count($self->{titleid});
}

sub title_nr {
    my ($self) = @_;
    $self->_vmg or return;
    $self->_vmg->title_nr($self->{titleid});
}

sub extract {
    my ($self, $outf, $progress) = @_;

    $progress ||= sub {};

    my $out;
    if (ref $outf eq 'GLOB') {
        $out = $outf;
    } else {
        open ($out, '>', $outf) or return;
    }

    my $pgc = $self->pgc(
        $self->pgc_id($self->_vmg->title_ttn($self->{titleid}), 1) || 0
    ) or return;

    my $dvdfile = DVD::Read::Dvd::File->new(
        $self->_dvd->{dvd},
        $self->title_nr,
        'VOB',
    ) or return;

    my $count = 0;
    my $cells_count = $pgc->cells_count;
    foreach my $cellid (
        map { $pgc->cell_number($_) }
        (1 .. $cells_count)) {
        my $cell = $pgc->cell($cellid);
        foreach my $sector ($cell->first_sector .. $cell->last_sector) {
            $progress->($cellid -1, $cells_count, $sector - $cell->first_sector,
            $cell->last_sector - $cell->first_sector +1); 
            my ($co, $data) = $dvdfile->readblock($sector, 1);
            $co or return;
            $count += $co;
            print $out $data;
        }
        $progress->($cellid, $cells_count, 0, 0);
    }

    if (ref $outf ne 'GLOB') {
        close($out);
    }

    return $count;
}

sub extract_chapter {
    my ($self, $chapter, $outf, $progress) = @_;

    $progress ||= sub {};

    my $out;
    if (ref $outf eq 'GLOB') {
        $out = $outf;
    } else {
        open ($out, '>', $outf) or return;
    }

    my @chapters = ref $chapter eq 'ARRAY'
        ? @{ $chapter }
        : ($chapter);

    my $dvdfile = DVD::Read::Dvd::File->new(
        $self->_dvd->{dvd},
        $self->title_nr,
        'VOB',
    ) or return;

    my $count = 0;
    my $chapter_count = 0;
    foreach my $ch (@chapters) {

        defined(my $fs = $self->chapter_first_sector($ch)) or return;
        defined(my $ls = $self->chapter_last_sector($ch))  or return;
        foreach($fs .. $ls) {
            $progress->($chapter_count, scalar(@chapters),
                        $_ - $fs, $ls - $fs);
            my ($co, $data) = $dvdfile->readblock($_, 1);
            $count += $co;
            print $out $data;
        }
        $chapter_count++;
        #finalyze
        $progress->($chapter_count, scalar(@chapters), 0, 0);
    }

    if (ref $outf ne 'GLOB') {
        close($out);
    }

    $count;
}

1;

__END__