Data::Conveyor::Exception::Handler - Stage-based conveyor-belt-like ticket handling system

use 5.008;
use strict;
use warnings;

package Data::Conveyor::Exception::Handler;
BEGIN {
  $Data::Conveyor::Exception::Handler::VERSION = '1.103130';
}

# ABSTRACT: Stage-based conveyor-belt-like ticket handling system
use Data::Miscellany 'class_map';
use parent 'Class::Scaffold::Storable';
use constant ERRCODE_FOR_EXCEPTION_CLASS_HASH => (
    UNIVERSAL => 'NC20000',    # fallback
);

sub RC_FOR_EXCEPTION_CLASS_HASH {
    local $_ = $_[0]->delegate;
    (   UNIVERSAL                    => $_->RC_INTERNAL_ERROR,    # fallback
        'Error::Hierarchy::Internal' => $_->RC_INTERNAL_ERROR,
        'Class::Value::Exception'    => $_->RC_ERROR,
        'Class::Scaffold::Exception::Business' => $_->RC_ERROR,
        'Data::Conveyor::Exception::Ticket'    => $_->RC_INTERNAL_ERROR,
        'Data::Conveyor::Exception::Ticket::MissingLock' => $_->RC_ERROR,
    );
}

sub STATUS_FOR_EXCEPTION_CLASS_HASH {
    local $_ = $_[0]->delegate;
    (   UNIVERSAL                              => $_->TS_ERROR,     # fallback
        'Error::Hierarchy::Internal'           => $_->TS_ERROR,
        'Class::Value::Exception'              => $_->TS_RUNNING,
        'Class::Scaffold::Exception::Business' => $_->TS_RUNNING,
        'Data::Conveyor::Exception::Ticket'    => $_->TS_ERROR,
        'Data::Conveyor::Exception::Ticket::MissingLock' => $_->TS_RUNNING,
    );
}

sub errcode_for_exception_class {
    my ($self, $class) = @_;
    class_map(
        $class,
        scalar $self->every_hash(
            'ERRCODE_FOR_EXCEPTION_CLASS_HASH',
            'exception.errcode_for_class',
        )
    );
}

sub rc_for_exception_class {
    my ($self, $exception) = @_;

    # Here we don't use the payload item, but a subclass might use it to
    # change the rc depending on the object type and command found in the
    # payload item.
    $self->delegate->make_obj(
        'value_ticket_rc',
        class_map(
            $exception,
            scalar $self->every_hash(
                'RC_FOR_EXCEPTION_CLASS_HASH', 'exception.rc_for_class',
            )
        )
    );
}

sub status_for_exception_class {
    my ($self, $exception) = @_;

    # Here we don't use the payload item, but a subclass might use it to
    # change the status depending on the object type and command found in the
    # payload item.
    $self->delegate->make_obj(
        'value_ticket_status',
        class_map(
            $exception,
            scalar $self->every_hash(
                'STATUS_FOR_EXCEPTION_CLASS_HASH',
                'exception.status_for_class',
            )
        )
    );
}
1;


__END__