Data::Conveyor::Monitor - Stage-based conveyor-belt-like ticket handling system

use 5.008;
use strict;
use warnings;

package Data::Conveyor::Monitor;
BEGIN {
  $Data::Conveyor::Monitor::VERSION = '1.103130';
}

# ABSTRACT: Stage-based conveyor-belt-like ticket handling system
use parent 'Class::Scaffold::Storable';

sub sort_by_stage_order {
    my ($self, @activity) = @_;
    my %stage_order;
    my $order = 1;
    $stage_order{$_} = sprintf "%02d" => $order++
      for map { "$_" }
      map {
        $self->delegate->make_obj('value_ticket_stage')->new_start($_),
          $self->delegate->make_obj('value_ticket_stage')->new_active($_),
          $self->delegate->make_obj('value_ticket_stage')->new_end($_),
      } $self->delegate->STAGE_ORDER;
    my @sorted =
      map  { $_->[0] }
      sort { $a->[1] cmp $b->[1] }
      map {
        [ $_, ($stage_order{ $_->{stage} } || '00') . ($_->{status} || ' ') ]
      } @activity;
    wantarray ? @sorted : \@sorted;
}

sub sif_top {
    my ($self, %opt) = @_;
    my $result = $self->delegate->make_obj('service_result_container');
    my @activity =
        $opt{all}
      ? $self->get_activity
      : $self->get_activity_running;
    $result->result_push(
        $self->delegate->make_obj('service_result_tabular')->set_from_rows(
            fields => [qw/count stage status rc oticket ochanged/],
            rows   => [ $self->sort_by_stage_order(@activity) ],
        )
    );
    $result->result_push(
        $self->delegate->make_obj(
            'service_result_scalar',
            result =>
              sprintf("%d open regtransfers\n", $self->count_open_regtransfers)
        )
    );
    $result;
}

sub get_activity {
    my $self = shift;
    $self->storage->get_activity;
}

sub get_activity_running {
    my $self = shift;
    $self->storage->get_activity_running;
}

sub count_open_regtransfers {
    my $self = shift;
    $self->storage->count_open_regtransfers;
}
1;


__END__