Data::Conveyor::Service::Util - Stage-based conveyor-belt-like ticket handling system

use 5.008;
use strict;
use warnings;

package Data::Conveyor::Service::Util;
BEGIN {
  $Data::Conveyor::Service::Util::VERSION = '1.103130';
}
# ABSTRACT: Stage-based conveyor-belt-like ticket handling system

#
# Mixin class for making service interface method implementations easier. It
# helps in interacting with the storage object. However, these helper methods
# make assumptions about the structure of the underlying storage calls. If
# these assumptions apply to your storage, you may find these methods useful.
use Error ':try';
use Error::Hierarchy::Util 'assert_nonempty_arrayref';

sub svc_check_arguments {
    my ($self, $passed_args, $supported_list) = @_;
    assert_nonempty_arrayref $supported_list,
      'list of supported parameters is empty';
    my $container = $self->delegate->make_obj('exception_container');
    my %supported = map { $_ => 1 } @$supported_list;
    my $exception;
    for my $arg (keys %$passed_args) {
        next if exists $supported{$arg};
        $container->record(
            'Error::Hierarchy::Internal::CustomMessage',
            custom_message => sprintf(
                "Unsupported parameter '%s'. (Supported: %s)" => $arg,
                join ', ' => @$supported_list
            )
        );
        $exception++;
    }
    $container->throw if $exception;
}

# FIXME
#
# This method makes assumptions on the structure of underlying storage calls,
# and is used by Registry::NICAT::Channel::Mail::Output and
# Registry::NICAT::Confirm.
#
# Is there a better place for it?
sub svc_result_for_storage_call {
    my ($self, $storage_call, $supported_args, %args) = @_;
    assert_nonempty_arrayref $supported_args,
      'list of supported parameters is empty';
    $storage_call
      || throw Error::Hierarchy::Internal::CustomMessage(
        custom_message => sprintf "bad call parameter '$storage_call'");
    $self->svc_check_arguments(\%args, $supported_args);
    $self->delegate->make_obj('service_result_scalar',
        result => scalar $self->storage->$storage_call(@args{@$supported_args})
    );
}
1;


__END__