Data::Conveyor::Storage - Stage-based conveyor-belt-like ticket handling system

use 5.008;
use strict;
use warnings;

package Data::Conveyor::Storage;
BEGIN {
  $Data::Conveyor::Storage::VERSION = '1.103130';
}
# ABSTRACT: Stage-based conveyor-belt-like ticket handling system

use Error::Hierarchy::Util 'assert_defined';
use Class::Scaffold::Exception::Util 'assert_object_type';
use parent 'Class::Scaffold::Base';
__PACKAGE__->mk_abstract_accessors(
    qw(
      ticket_update ticket_insert get_ticket_shift_data
      )
);

# Within Data-Conveyor, rollback_mode isn't taken from the superclass'
# property of the same name, but we ask the delegate.
# Class::Scaffold::App::Test will set the rollback_mode on the Environment
# (which is the delegate), for example.  Just be sure to place
# Data::Conveyor::Storage first in multiple inheritance, e.g., when inheriting
# both from Data::Conveyor::Storage and Data::Storage::*
sub rollback_mode       { $_[0]->delegate->rollback_mode }
sub set_rollback_mode   { $_[0]->delegate->set_rollback_mode }
sub clear_rollback_mode { $_[0]->delegate->clear_rollback_mode }

sub ticket_store {
    my ($self, $ticket) = @_;
    $ticket->assert_ticket_no;
    if ($self->ticket_exists($ticket)) {
        $self->ticket_update($ticket);
    } else {
        $self->ticket_insert($ticket);
    }
}

sub ticket_serialized_payload {
    my ($self, $payload) = @_;
    assert_object_type $payload, 'ticket_payload';
    $payload->version($self->delegate->PAYLOAD_VERSION);

    # Serialize the ticket payload using Storable. The serialized version is
    # stored in the dem_payload table. We need to enable the serialization of
    # code references.
    require Storable;
    $Storable::Deparse = 1;
    $payload           = Storable::nfreeze($payload);

    # compression
    require Compress::Zlib;
    Compress::Zlib::compress($payload)
      || throw Error::Hierarchy::Internal::CustomMessage(
        custom_message => 'zlib compress() failure');
}

sub ticket_deserialized_payload {
    my ($self, $payload) = @_;
    assert_defined $payload, 'called without defind serialized payload.';

    # compression
    require Compress::Zlib;
    $payload = Compress::Zlib::uncompress($payload)
      || throw Error::Hierarchy::Internal::CustomMessage(
        custom_message => 'zlib uncompress() failure');

    # deserialize the ticket payload using Storable if it exists.
    # we need to enable the deserialization of code references.
    require Storable;
    $Storable::Eval = 1;
    $payload        = Storable::thaw($payload);
    $payload->upgrade;
    $payload;
}

sub ticket_handle_exception {
    my ($self, $E) = @_;
    throw $E;
}
1;


__END__