Data::Conveyor::Ticket::Processor::Conveyor - Stage-based conveyor-belt-like ticket handling system

use 5.008;
use strict;
use warnings;

package Data::Conveyor::Ticket::Processor::Conveyor;
BEGIN {
  $Data::Conveyor::Ticket::Processor::Conveyor::VERSION = '1.103130';
}
# ABSTRACT: Stage-based conveyor-belt-like ticket handling system

use parent 'Class::Scaffold::Storable';
__PACKAGE__->mk_framework_object_accessors(ticket => 'ticket')
  ->mk_scalar_accessors(qw(poll_delegate))
  ->mk_boolean_accessors(qw(transactional_authority));

# the poll delegate allows the upper service layer to interrupt processing
# by throwing an exception, if it thinks it is necessary.
use constant DEFAULTS => (transactional_authority => 1);

sub run {
    my $self           = shift;
    my $previous_stage = '';
    while ($self->ticket->stage ne $previous_stage) {
        last if $self->ticket->stage eq $self->delegate->FINAL_TICKET_STAGE;
        $previous_stage = $self->ticket->stage;
        if (   $self->poll_delegate
            && $self->poll_delegate->can('callback')) {
            $self->poll_delegate->callback($self->ticket);
        }

        # We need to set the ticket to active, because it won't have been
        # open()ed - we just process a ticket from start to end, without
        # repeatedly writing and re-reading it.
        $self->ticket->stage->set_active;
        $self->delegate->make_obj('ticket_dispatcher')
          ->new(transactional_authority => $self->transactional_authority)
          ->dispatch($self->ticket);
    }
    $self->ticket->store;
}
1;


__END__