Data::ObjectDriver::Driver::Partition - base class for partitioned object drivers

Data-ObjectDriver documentation Contained in the Data-ObjectDriver distribution.

Index

Code Index:

NAME

Top

Data::ObjectDriver::Driver::Partition - base class for partitioned object drivers

SYNOPSIS

Top

    package SomeObject;

    __PACKAGE__->install_properties({
        ...
        primary_key => 'id',
        driver      => Data::ObjectDriver::Driver::Partition->new(get_driver => \&find_partition),
    });

    # Say we have a list of 5 arrayrefs of the DBI driver information.
    my @DBI_INFO;

    sub find_partition {
        my ($part_key, $args) = @_;

        my $id;

        if (ref $terms && ref $terms eq 'HASH') {
            # This is a search($terms, $args) call.
            my $terms = $part_key;
            $id = $terms->{id}
                or croak "Can't determine partition from a search() with no id field";
        }
        else {
            # This is a lookup($id) or some method invoked on an object where we know the ID.
            my $id = $part_key;
        }

        # "ID modulo N" is not a good partitioning strategy, but serves as an example.
        my $partition = $id % 5;
        return Data::ObjectDriver::Driver::DBI->new( @{ $DBI_INFO[$partition] } );
    }

DESCRIPTION

Top

Data::ObjectDriver::Driver::Partition provides the basic structure for partitioning objects into different databases. Using partitions, you can horizontally scale your application by using different database servers to hold sets of data.

To partition data, you need a certain criteria to determine which partition data goes in. Partition drivers use a get_driver function to find the database driver for the correct partition, given either the arguments to a search() or the object's primary key for a lookup(), update(), etc where the key is known.

SUGGESTED PRACTICES

Top

While you can use any stable, predictable method of selecting the partition for an object, the most flexible way is to keep an unpartitioned table that maps object keys to their partitions. You can then look up the appropriate record in your get_driver method to find the partition.

For many applications, you can partition several classes of data based on the ID of the user account that "owns" them. In this case, you would include the user ID as the first part of a complex primary key.

Because multiple objects can use the same partitioning scheme, often Data::ObjectDriver::Driver::Partition is subclassed to define the get_driver function once and automatically specify it to the Data::ObjectDriver::Driver::Partition constructor.

Note these practices are codified into the Data::ObjectDriver::Driver::SimplePartition class.

USAGE

Top

Data::ObjectDriver::Driver::Partition->new(%params)

Creates a new partitioning driver. The required members of %params are:

* get_driver

A reference to a function to be used to retrieve for a given object or set of search terms. Your function is invoked as either:

* get_driver(\%terms, \%args)

Return a driver based on the given search() parameters.

* get_driver($id)

Return a driver based on the given object ID. Note that $id may be an arrayref, if the class was defined with a complex primary key.

* pk_generator

A reference to a function that, given a data object, generates a primary key for it. This is the same pk_generator given to Data::ObjectDriver's constructor.

$driver->search($class, $terms, $args)

$driver->lookup($class, $id)

$driver->lookup_multi($class, @ids)

$driver->exists($obj)

$driver->insert($obj)

$driver->update($obj)

$driver->remove($obj)

$driver->fetch_data($what)

Performs the named action, by passing these methods through to the appropriate database driver as determined by $driver's get_driver function.

DIAGNOSTICS

Top

No errors are created by Data::ObjectDriver::Driver::Partition itself. Errors may come from a specific partitioning subclass or the driver for a particular database.

BUGS AND LIMITATIONS

Top

There are no known bugs in this module.

SEE ALSO

Top

Data::ObjectDriver::Driver::SimplePartition

LICENSE

Top

Data::ObjectDriver is free software; you may redistribute it and/or modify it under the same terms as Perl itself.

AUTHOR & COPYRIGHT

Top

Except where otherwise noted, Data::ObjectDriver is Copyright 2005-2006 Six Apart, cpan@sixapart.com. All rights reserved.

Data-ObjectDriver documentation Contained in the Data-ObjectDriver distribution. 
# $Id$

package Data::ObjectDriver::Driver::Partition;
use strict;
use warnings;
use Carp();

use base qw( Data::ObjectDriver Class::Accessor::Fast );

__PACKAGE__->mk_accessors(qw( get_driver ));

sub init {
    my $driver = shift;
    $driver->SUPER::init(@_);
    my %param = @_;
    $driver->get_driver($param{get_driver});
    $driver->{__working_drivers} = [];
    $driver;
}

sub lookup {
    my $driver = shift;
    my($class, $id) = @_;
    return unless $id;
    $driver->get_driver->($id)->lookup($class, $id);
}

sub lookup_multi {
    my $driver = shift;
    my($class, $ids) = @_;
    return [] unless @$ids;
    $driver->get_driver->($ids->[0])->lookup_multi($class, $ids);
}

sub exists     { shift->_exec_partitioned('exists',     @_) }
sub insert     { shift->_exec_partitioned('insert',     @_) }
sub replace    { shift->_exec_partitioned('replace',    @_) }
sub update     { shift->_exec_partitioned('update',     @_) }
sub remove     { shift->_exec_partitioned('remove',     @_) }
sub fetch_data { shift->_exec_partitioned('fetch_data', @_) }

sub search {
    my $driver = shift;
    my($class, $terms, $args) = @_;
    $driver->get_driver->($terms, $args)->search($class, $terms, $args);
}

sub _exec_partitioned {
    my $driver = shift;
    my($meth, $obj, @rest) = @_;
    ## If called as a class method, pass in the stuff in @rest.
    my $d;
    if (ref($obj)) {
        my $terms = $obj->column_values;
        # @rest should only contain $args, but just in case
        # don't assume we have nothing else and build @rest2
        (undef, my @rest2) = @rest;
        $d = $driver->get_driver->($terms, @rest2);
    } else {
        $d = $driver->get_driver->(@rest);
    }

    if ( $driver->txn_active ) {
        $driver->add_working_driver($d);
    }
    $d->$meth($obj, @rest);
}

sub add_working_driver {
    my $driver = shift;
    my $part_driver = shift;
    if (! $part_driver->txn_active) {
        $part_driver->begin_work;
        push @{$driver->{__working_drivers}}, $part_driver;
    }
}

sub commit {
    my $driver = shift;

    ## if the driver has its own internal txn_active flag
    ## off, we don't bother ending. Maybe we already did
    return unless $driver->txn_active;

    $driver->SUPER::commit(@_);
    _end_txn($driver, 'commit', @_);
}

sub rollback {
    my $driver = shift;

    ## if the driver has its own internal txn_active flag
    ## off, we don't bother ending. Maybe we already did
    return unless $driver->txn_active;

    $driver->SUPER::rollback(@_);
    _end_txn($driver, 'rollback', @_);
}

sub _end_txn {
    my ($driver, $method) = @_;

    my $wd = $driver->{__working_drivers};
    $driver->{__working_drivers} = [];

    for my $part_driver (@{ $wd || [] }) {
        $part_driver->$method;
    }
}


1;

__END__