Data::Stream::Bulk::DoneFlag - Implement the C<is_done> method in terms of a flag

Data-Stream-Bulk documentation Contained in the Data-Stream-Bulk distribution.

Index

Code Index:

NAME

Top

Data::Stream::Bulk::DoneFlag - Implement the is_done method in terms of a flag

SYNOPSIS

Top

    package Data::Stream::Bulk::Blah;
    use Moose;

    with qw(Data::Stream::Bulk::DoneFlag);

    sub get_more {
        if ( my @more = more() ) {
            return \@more;
        } else {
            return;
        }
    }

DESCRIPTION

Top

This role implements the Data::Stream::Bulk core API in terms of one method (get_more).

As a convenience it calls finished when the stream is exhausted, so that cleanup may be done.

This is used by classes like Data::Stream::Bulk::DBI, Data::Stream::Bulk::Callback.

METHODS

Top

is_done

Returns the state of the iterator.

next

As long as the iterator is not yet done, calls get_more.

If get_more returned a false value instead of an array reference then done is set, finished is called, and this next does nothing on subsequent calls.

finished

A noop by default. Can be overridden if so desired.

REQUIRED METHODS

Top

get_more

Returns the next block of data as an array ref, or a false value if no items are left.

AUTHOR

Top

Yuval Kogman <nothingmuch@woobling.org>

COPYRIGHT AND LICENSE

Top

This software is copyright (c) 2010 by Yuval Kogman.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

Data-Stream-Bulk documentation Contained in the Data-Stream-Bulk distribution. 
package Data::Stream::Bulk::DoneFlag;
BEGIN {
  $Data::Stream::Bulk::DoneFlag::AUTHORITY = 'cpan:NUFFIN';
}
BEGIN {
  $Data::Stream::Bulk::DoneFlag::VERSION = '0.08';
}
# ABSTRACT: Implement the C<is_done> method in terms of a flag

use Moose::Role;

use namespace::clean -except => 'meta';

with qw(Data::Stream::Bulk);

requires "get_more";

sub is_done {}
has done => (
    isa => "Bool",
    init_arg => undef,
    reader => "is_done",
    writer => "_done",
);

sub finished {}

sub _set_done {
    my $self = shift;
    $self->_done(1);
    $self->finished;
}

sub next {
    my $self = shift;

    unless ( $self->is_done ) {
        if ( my $more = $self->get_more ) {
            return $more;
        } else {
            $self->_set_done;
            return;
        }
    } else {
        return;
    }
}

__PACKAGE__;


__END__