DateTime::Event::Klingon - Determine events of Klingon cultural significance

    use DateTime;
    use DateTime::Event::Klingon qw/Heghlu'meH QaQ jajvam'a'/;

    my $dt = DateTime->now;
    print 'Today ', Heghlu'meH QaQ jajvam'a'($dt) ? 'is' : 'is not', 
        " a good day to die!\n";  

    perldoc DateTime::Event::Klingon

# $Id: /svn/DateTime-Event-Klingon/tags/VERSION_1_0_1/lib/DateTime/Event/Klingon.pm 323 2008-04-01T06:37:25.246199Z jaldhar  $
package DateTime::Event::Klingon;

use warnings;
use strict;
use Carp qw/croak/;
use Filter::Util::Call;
use UNIVERSAL qw/isa/;

our $VERSION = '1.0';

sub import {
    my ( $self, @args ) = @_;

    my $joinedargs = join q{ }, @args;
    if ( $joinedargs =~ /Heghlu'meH\ QaQ\ jajvam'a'/mx ) {
        {
            no strict 'refs';
            my $caller = caller;

            *{"${caller}::_heghlu_meh_qaq_jajvam_a_"}
                = \&{'_heghlu_meh_qaq_jajvam_a_'};
        }

        return filter_add(
            sub {
                my $count = 0;
                my $status;
                my $data = q{};
                while ( $status = filter_read() ) {
                    if ( $status < 0 ) {
                        return $status;
                    }
                    if ( $status == 0 ) {
                        last;
                    }
                    $data .= $_;
                    $count++;
                    $_ = q{};
                }
                if ( $count == 0 ) {
                    return 0;
                }
                $_ = $data;
                s{ Heghlu'meH\ QaQ\ jajvam'a'(\s*\() }
                                  { _heghlu_meh_qaq_jajvam_a_$1  }gmx;
                return $count;
            }
        );
    }
}

sub _heghlu_meh_qaq_jajvam_a_ {
    my ($dt) = @_;

    if ( !isa( $dt, 'DateTime' ) ) {
        croak q{Hab SoSlI' Quch!};
    }
    return 1;
}

1;    # End of DateTime::Event::Klingon