Devel::Events::Handler::Multiplex - Delegate events to multiple handlers

Devel-Events documentation

Contained in the Devel-Events distribution.

Index

NAME
SYNOPSIS
DESCRIPTION
METHODS

Code Index:

package Devel::Events::Handler::Multiplex
__END__
EOF

NAME

Devel::Events::Handler::Multiplex - Delegate events to multiple handlers

SYNOPSIS

	use Devel::Events::Handler::Multiplex;

	my $h = Devel::Events::Handler::Multiplex->new(
		handlers => \@handlers,
	);

	$h->add_handler( $other_handler );

	$h->new_event( ... );

	$h->remove_handler( $some_handler );

DESCRIPTION

This handler repeats events to any number of sub handlers.

It is useful as a central hub, delegating to any number of sub listeners, from any number of generators.

METHODS

new_event @handlers: Delegates the event to every one of the sub handlers.
handlers: Lists the handlers
add_handler $handler: Add a handler to the set of registered handlers.
remove_handler $handler: Remove a handler from the set of registered handlers.

Devel-Events documentation

Contained in the Devel-Events distribution.

#!/usr/bin/perl

package Devel::Events::Handler::Multiplex;
use Moose;

with qw/Devel::Events::Handler/;

use Set::Object;

has '_handlers' => (
	is        => 'ro',
	isa       => 'Set::Object',
	default   => sub { Set::Object->new },
);

sub BUILD {
	my ( $self, $param ) = @_;

	if ( my $handlers = $param->{handlers} ) {
		$self->add_handler( @$handlers );
	}
}

sub add_handler {
	my ( $self, @h ) = @_;
	$self->_handlers->insert(@h);
}

sub remove_handler {
	my ( $self, @h ) = @_;
	$self->_handlers->remove(@h);
}

sub handlers {
	my ( $self, @h ) = @_;

	if ( @h ) {
		$self->_handlers( Set::Object->new(@h) );
	}

	$self->_handlers->members;
}

sub new_event {
	my ( $self, @event ) = @_;

	foreach my $handler ( $self->handlers ) {
		$handler->new_event(@event);
	}
}

__PACKAGE__;

__END__