Dist::Zilla::Plugin::Git::Tag - tag the new version

Dist-Zilla-Plugin-Git documentation

Contained in the Dist-Zilla-Plugin-Git distribution.

Index

NAME
VERSION
SYNOPSIS
DESCRIPTION
METHODS
- tag
AUTHOR
COPYRIGHT AND LICENSE

Code Index:

package Dist::Zilla::Plugin::Git::Tag
__END__
EOF

NAME

Dist::Zilla::Plugin::Git::Tag - tag the new version

VERSION

version 1.111590

SYNOPSIS

In your dist.ini:

    [Git::Tag]
    tag_format  = v%v       ; this is the default
    tag_message = v%v       ; this is the default

DESCRIPTION

Once the release is done, this plugin will record this fact in git by creating a tag. By default, it makes an annotated tag. You can set the tag_message attribute to change the message. If you set tag_message to the empty string, it makes a lightweight tag.

It also checks before the release to ensure the tag to be created doesn't already exist. (You would have to manually delete the existing tag before you could release the same version again, but that is almost never a good idea.)

Plugin options

The plugin accepts the following options:

* tag_format - format of the tag to apply. Defaults to v%v, see Formatting options below.
* tag_message - format of the commit message. Defaults to v%v, see Formatting options below. Use tag_message = to create a lightweight tag.
* time_zone - the time zone to use with %d. Can be any time zone name accepted by DateTime. Defaults to local.
* branch - which branch to tag. Defaults to current branch.

Formatting options

Some plugin options allow you to customize the tag content. You can use the following codes at your convenience:

%{dd-MMM-yyyy}d: The current date. You can use any CLDR format supported by DateTime. A bare %d means %{dd-MMM-yyyy}d.
%n: A newline
%N: The distribution name
%{-TRIAL}t: Expands to -TRIAL (or any other supplied string) if this is a trial release, or the empty string if not. A bare %t means %{-TRIAL}t.
%v: The distribution version

METHODS

tag

    my $tag = $plugin->tag;

Return the tag that will be / has been applied by the plugin. That is, returns tag_format as completed with the real values.

AUTHOR

Jerome Quelin

COPYRIGHT AND LICENSE

This software is copyright (c) 2009 by Jerome Quelin.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

Dist-Zilla-Plugin-Git documentation

Contained in the Dist-Zilla-Plugin-Git distribution.

#
# This file is part of Dist-Zilla-Plugin-Git
#
# This software is copyright (c) 2009 by Jerome Quelin.
#
# This is free software; you can redistribute it and/or modify it under
# the same terms as the Perl 5 programming language system itself.
#
use 5.008;
use strict;
use warnings;

package Dist::Zilla::Plugin::Git::Tag;
BEGIN {
  $Dist::Zilla::Plugin::Git::Tag::VERSION = '1.111590';
}
# ABSTRACT: tag the new version

use Git::Wrapper;
use Moose;
use MooseX::Has::Sugar;
use MooseX::Types::Moose qw{ Str };
use String::Formatter method_stringf => {
  -as => '_format_tag',
  codes => {
    d => sub { require DateTime;
               DateTime->now(time_zone => $_[0]->time_zone)
                       ->format_cldr($_[1] || 'dd-MMM-yyyy') },
    n => sub { "\n" },
    N => sub { $_[0]->zilla->name },
    t => sub { $_[0]->zilla->is_trial
                 ? (defined $_[1] ? $_[1] : '-TRIAL') : '' },
    v => sub { $_[0]->zilla->version },
  },
};

with 'Dist::Zilla::Role::BeforeRelease';
with 'Dist::Zilla::Role::AfterRelease';


# -- attributes

has tag_format  => ( ro, isa=>Str, default => 'v%v' );
has tag_message => ( ro, isa=>Str, default => 'v%v' );
has time_zone   => ( ro, isa=>Str, default => 'local' );
has branch => ( ro, isa=>Str, predicate=>'has_branch' );


has tag => ( ro, isa => Str, lazy_build => 1, );

sub _build_tag
{
    my $self = shift;
    return _format_tag($self->tag_format, $self);
}


# -- role implementation

sub before_release {
    my $self = shift;
    my $git  = Git::Wrapper->new('.');

    # Make sure a tag with the new version doesn't exist yet:
    my $tag = $self->tag;
    $self->log_fatal("tag $tag already exists")
        if $git->tag('-l', $tag );
}

sub after_release {
    my $self = shift;
    my $git  = Git::Wrapper->new('.');

    # Make an annotated tag if tag_message, lightweight tag otherwise:
    my @opts = $self->tag_message
        ? ( '-m' => _format_tag($self->tag_message, $self) )
        : ();
    my @branch = $self->has_branch ? ( $self->branch ) : ();

    # create a tag with the new version
    my $tag = $self->tag;
    $git->tag( @opts, $tag, @branch );
    $self->log("Tagged $tag");
}

1;


__END__