Egg::Exception - The exception with stack trace is generated.

Egg-Release documentation Contained in the Egg-Release distribution.

Index

Code Index:

NAME

Top

Egg::Exception - The exception with stack trace is generated.

SYNOPSIS

Top

  use Egg::Exception;

  Egg::Error->throw('The error occurs.');

  or

  local $SIG{__DIE__}= sub { Egg::Error->throw(@_) };
  die 'The error occurs.';

DESCRIPTION

Top

It is a module to vomit the message with stack trace when the exception is generated.

METHODS

Top

new

Constructor. This is internally called.

throw ([MESSAGE_STRING])

After the constructor is let pass, the exception is generated.

  Egg::Error->throw( 'internal error.' );

stacktrace

Only trace information on the object is returned.

  local $SIG{__DIE__}= sub { Egg::Error->throw(@_) };
  eval{ ... code. };
  if ($@) { die $@->stacktrace }

frames

Trace information on the object is returned by the ARRAY reference.

  local $SIG{__DIE__}= sub { Egg::Error->throw(@_) };
  eval{ ... code. };
  if ($@) { die join "\n", @{$@->frames} }

as_string

as_string of Devel::StackTrace is returned.

  local $SIG{__DIE__}= sub { Egg::Error->throw(@_) };
  eval{ ... code. };
  if ($@) { die $@->as_string }

errstr

Only the exception message of the object is returned.

  local $SIG{__DIE__}= sub { Egg::Error->throw(@_) };
  eval{ ... code. };
  if ($@) { die $@->errstr }

SEE ALSO

Top

Egg::Release, Devel::StackTrace,

AUTHOR

Top

Masatoshi Mizuno, <lushe&64;cpan.org>

COPYRIGHT AND LICENSE

Top

Copyright (C) 2008 Bee Flag, Corp. <http://egg.bomcity.com/>.

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself, either Perl version 5.8.6 or, at your option, any later version of Perl 5 you may have available.

Egg-Release documentation Contained in the Egg-Release distribution. 
package Egg::Exception;
#
# Masatoshi Mizuno E<lt>lusheE<64>cpan.orgE<gt>
#
# $Id: Exception.pm 337 2008-05-14 12:30:09Z lushe $
#
use strict;
use warnings;

our $VERSION= '3.00';

package Egg::Error;
use strict;
use warnings;
use Devel::StackTrace;
use overload  '""' => 'stacktrace';
use base qw/ Class::Accessor::Fast /;

our $IGNORE_PACKAGE= [qw/ main Carp /];
our $IGNORE_CLASS  = [qw/ Egg::Error /];

__PACKAGE__->mk_accessors(qw/ errstr frames as_string /);

sub new {
	my $class = shift;
	my $errstr= join '', @_;
	my $stacktrace;
	{
		local $@;
		eval{
		  $stacktrace= Devel::StackTrace->new(
		    ignore_package   => $IGNORE_PACKAGE,
		    ignore_class     => $IGNORE_CLASS,
		    no_refs          => 1,
		    respect_overload => 1,
		    );
		  };
	  };
	die $errstr unless $stacktrace;
	bless {
	  errstr   => $errstr,
	  as_string=> $stacktrace->as_string,
	  frames   => [$stacktrace->frames],
	  }, $class;
}
sub throw {
	my $error= shift->new(@_);
	die $error;
}
sub stacktrace {
	my($self)= @_;
	my @trace;
	foreach my $f (@{$self->frames}) {
		push @trace, $f->filename. ': '. $f->line;
	}
	"$self->{errstr} \n\n stacktrace: \n [". join("] \n [", @trace). "] \n";
}

1;

__END__