Email::Store::Header - plugin to Email::Store to parse and save message headers

    use Email::Store::Header;

  

package Email::Store::Header;

use warnings;
use strict;
use Carp;

use version; our $VERSION = qv('0.0.4');

# Other recommended modules (uncomment to use):
#  use IO::Prompt;
#  use Perl6::Export;
#  use Perl6::Slurp;
#  use Perl6::Say;

use Mail::Header;
use base qw{ Email::Store::DBI };


# Module implementation here
__PACKAGE__->table('header');
__PACKAGE__->columns( All => qw[ id mail header value ] );
__PACKAGE__->has_a(mail => 'Email::Store::Mail');
Email::Store::Mail->has_many(headers => 'Email::Store::Header');

sub on_store {
    my ($class, $mail) = @_;

    my $rfc822      = $mail->message;
    my @lines       = split m{ \n }x, $rfc822;
    my $head        = new Mail::Header \@lines;

    # Remove any header line that, other than the tag, only contains whitespace
    $head->cleanup;

    my @tags        = $head->tags;
    my $head_hash   = $head->header_hashref;

    # loop through all the tags and store them
    foreach my $tag (@tags) {
        # get a list of all instances of $tag in the mail header
        my $tag_value = $head_hash->{ $tag };

        if ('ARRAY' eq ref($tag_value)) {
            # loop through the list
            foreach my $value (@$tag_value) {
                chomp $value;

                $class->_store_header(
                    $mail,
                    $tag,
                    $value,
                );
            }
        }
        else {
            # it's just a scalar
            chomp $tag_value;
            $class->_store_header(
                $mail,
                $tag,
                $tag_value,
            );
        }
    }

    undef $mail->{simple}; # Invalidate cache
    $mail->update;
}

sub on_store_order { 1 };


sub _store_header {
    my ($class, $mail, $header, $value) = @_;

    $class->create(
        {
            mail    =>  $mail->id,
            header  =>  $header,
            value   =>  $value,
        }
    );
}



1; # Magic true value required at end of module

__END__

__DATA__
CREATE TABLE IF NOT EXISTS header (
    id INTEGER auto_increment NOT NULL PRIMARY KEY,
    mail text NOT NULL,
    header text NOT NULL,
    value text NOT NULL
);