Every - return true every N cycles or S seconds

Every documentation Contained in the Every distribution.

Index

Code Index:

NAME

Top

Every - return true every N cycles or S seconds

SYNOPSIS

Top

 for (0..200)
 {
  print_stats() if every(20);           # every 20 cycles
  print_times() if every(seconds => 5); # every 5 or more seconds
  sleep 3;
 }

FUNCTION-ORIENTED INTERFACE

Top

every( $number [, @id] )

every( seconds => $number [, @id] )

Returns true every $number times it's called, or every time $number seconds have elapsed since the last time it was called.

The every() function keeps track of where it was called by line, even if you call it twice on the same line, e.g.

 print "hello" if every(5) or every(6);

The every() function will use the Devel::Callsite module to find the opcode and interpreter context (both unique numbers).

The optional @id is a list of arguments that compose a unique identifier. In other words, every(100, 'x') will run its 100 cycles independently of every(100, 'x', 'y').

DESCRIPTION

Top

Returns true when the conditions (cycles or seconds elapsed) are met. The first cycle doesn't count (so e.g. every(100) will be true at 100, 200, etc.)

Thanks to Dr.Ruud on comp.lang.perl.misc for helping with this idea, and to Jerry Hedden for cleaning it up. Thanks to Ben Morrow for getting Devel::Callsite started, which module is essential to Every.

Thanks to Jerrad Pierce and ikegami for the bug reports and help.

BUGS

Top

None known.

COPYRIGHT

Top

Copyright 2008, Ted Zlatanov (Теодор Златанов). All Rights Reserved. This module can be redistributed under the same terms as Perl itself.

AUTHOR

Top

Ted Zlatanov <tzz@lifelogs.com>

SEE ALSO

Top

Every documentation Contained in the Every distribution. 
#!/usr/bin/perl

package Every;

use Devel::Callsite;
use strict;
use warnings;

our $VERSION = '0.08';
$VERSION = eval $VERSION;

use Exporter;
our @ISA = qw(Exporter);
our @EXPORT = qw(every);

use Scalar::Util qw(looks_like_number);

my %counters;
my %time_counters;

# Arg must be defined and be a positive number
sub _check_arg
{
    my $arg = $_[0];

    if (! defined($arg)) {
        require Carp;
        Carp::croak('Argument missing or undefined');
    }
    if (! Scalar::Util::looks_like_number($arg)) {
        require Carp;
        Carp::croak('Argument is not numeric');
    }
    if ($arg <= 0) {
        require Carp;
        Carp::croak('Argument must be greater than zero');
    }
}

sub every
{
    my ($div, @id) = @_;

    my $site = callsite() . '/' . context();
    
    if (defined($div) && ($div =~ /^sec/)) {    # Allows 'seconds', 'secs', etc.
        my $now = time();   # Capture current time

        $div = shift(@id);
        _check_arg($div);   # Validate arg

        my $key = join('_', caller(), $div, $site, @id);  # Hash key

        if (my $then = $time_counters{$key}) {
            my $diff = $now - ($then + $div);
            return ($diff >= 0) ? ($time_counters{$key} = $now) : 0;
        } else {
            # First time called
            $time_counters{$key} = $now;
            return;
        }
    }

    _check_arg($div);
    if (int($div) != $div) {    # Non-timer arg should also be an integer
        require Carp;
        Carp::croak('Argument is not an integer');
    }

    my $key = join('_', caller(), $div, $site, @id);   # Hash key
    return !(++$counters{$key} % $div) ? 1 : 0;
}

1;

__END__