ExtUtils::FindFunctions - Find functions in external libraries

ExtUtils-FindFunctions documentation Contained in the ExtUtils-FindFunctions distribution.

Index

Code Index:

NAME

Top

ExtUtils::FindFunctions - Find functions in external libraries

VERSION

Top

Version 0.02

SYNOPSIS

Top

    use ExtUtils::FindFunctions;

    my @check = qw(pcap_findalldevs  pcap_open_dead  pcap_setnonblock  pcap_lib_version);
    my @funcs = have_functions(libs => '-lpcap', funcs => \@check, return_as => 'array');

DESCRIPTION

Top

This module provides the have_functions() function which can be used to check if given functions are provided by an external library. Its aim is to be used as an embedded library by Makefile.PL which needs such facilities. Use the install-extutils-findfunctions command to embed it in your distribution.

EXPORT

Top

The module exports by default the have_functions() function.

FUNCTIONS

Top

have_functions()

Load the specified libraries and search for the given functions names. The results are returned as an array or as an hash depending on the return_as parameter.

Parameters

AUTHOR

Top

Sébastien Aperghis-Tramoni, <sebastien at aperghis.net>

BUGS

Top

Please report any bugs or feature requests to bug-extutils-findfunctions at rt.cpan.org, or through the web interface at http://rt.cpan.org/NoAuth/ReportBug.html?Queue=ExtUtils-FindFunctions. I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

SUPPORT

Top

You can find documentation for this module with the perldoc command.

    perldoc ExtUtils::FindFunctions

You can also look for information at:

* AnnoCPAN: Annotated CPAN documentation

http://annocpan.org/dist/ExtUtils-FindFunctions

* CPAN Ratings

http://cpanratings.perl.org/d/ExtUtils-FindFunctions

* RT: CPAN's request tracker

http://rt.cpan.org/NoAuth/Bugs.html?Dist=ExtUtils-FindFunctions

* Search CPAN

http://search.cpan.org/dist/ExtUtils-FindFunctions

COPYRIGHT & LICENSE

Top

Copyright 2006 Sébastien Aperghis-Tramoni, all rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

ExtUtils-FindFunctions documentation Contained in the ExtUtils-FindFunctions distribution. 
package ExtUtils::FindFunctions;
use strict;
use Carp;
use DynaLoader;
require Exporter;

{   no strict;
    $VERSION = '0.02';
    @ISA     = qw(Exporter);
    @EXPORT  = qw(&have_functions);
}


sub have_functions {
    my %args = @_;
    my %funcs = ();

    # check params
    defined $args{$_} or croak "error: Missing parameter '$_'.\n" for qw(libs funcs return_as);

    $args{return_as} ||= 'array';
    $args{return_as} =~ /^(?:array|hash)$/
        or croak "error: Incorrect value for parameter 'return_as'.\n";

    my @libs = ref $args{libs} eq ''      ? $args{libs}
             : ref $args{libs} eq 'ARRAY' ? @{$args{libs}}
             : croak "error: Incorrect argument for parameter 'libs'.\n";

    # search for functions
    for my $lib (@libs) {
        my @paths = DynaLoader::dl_findfile($lib);

        for my $path (@paths) {
            my $libref = DynaLoader::dl_load_file($path);

            for my $func (@{$args{funcs}}) {
                my $symref = DynaLoader::dl_find_symbol($libref, $func);
                $funcs{$func} = ! ! defined $symref;
            }

            DynaLoader::dl_unload_file($libref);
        }
    }

    return $args{return_as} eq 'hash' ? %funcs
           : grep { $funcs{$_} } sort keys %funcs;
}



1; # End of ExtUtils::FindFunctions