File::Append::TempFile - Perl extension for appending data to files

  use File::Append::TempFile;

  $f = new File::Append::TempFile();
  $f->begin_work('/etc/hosts') or die "Appending: ".$f->err();
  $f->add_line("127.0.0.2 localhvost\n");
  $f->commit();

  $f->begin_work('/etc/hosts') or die "Appending: ".$f->err();
  $f->add_line("...\n");
  $f->rollback();

  http://devel.ringlet.net/sysutils/file-append-tempfile/

package File::Append::TempFile;

use 5.006;
use strict;
use warnings;

use Fcntl;

our @ISA = qw();

our $VERSION = '0.05';

our $debug = 0;

my %tempfiles;

sub new
{
	my $proto = shift;
	my $class = ref $proto || $proto;
	my $self;

	$self = { 'fname' => undef, 'tmpfname' => undef, 'f' => undef,
	    'err' => undef, 'debug' => undef };
	bless $self, $class;
	$tempfiles{$self} = $self;
	return $self;
}

sub err($ $)
{
	my ($self, $err) = @_;

	$self->{'err'} = $err if @_ > 1;
	return $self->{'err'};
}

sub diag($ $)
{
	my ($self, $debug) = @_;

	$self->{'debug'} = $debug if @_ > 1;
	return $self->{'debug'};
}

sub begin_work($ $)
{
	my ($self, $fname) = @_;
	my ($tmpfname, $orig, $f);
	my @stat;

	if ($self->{'f'}) {
		return undef unless $self->rollback();
	}
	$self->{'fname'} = $self->{'tmpfname'} = $self->{'f'} = undef;

	if (!open($orig, '<', $fname)) {
		$self->err("Opening $fname: $!");
		return undef;
	}
	@stat = stat $orig;
	$tmpfname = sprintf '%s.%05d.%04d', $fname, $$, int rand 10000;
	if (!sysopen($f, $tmpfname, O_WRONLY | O_EXCL | O_CREAT, 0600)) {
		$self->err("Creating temporary file $tmpfname: $!");
		return undef;
	}
	return undef unless $self->do_copy($orig, $f);
	close $orig;

	$self->{'fname'} = $fname;
	$self->{'tmpfname'} = $tmpfname;
	$self->{'f'} = $f;
	$self->{'stat'} = [ @stat ];
	return 1;
}

sub add_line($ $)
{
	my ($self, $line) = @_;
	my $f = $self->{'f'};

	if (!defined($f)) {
		$self->err("Cannot add_line() to an unopened tempfile");
		return undef;
	}
	$self->debug("RDBG about to add a line to $self->{tmpfname} for $self->{fname}\n");
	if (!(print $f $line)) {
		$self->err("Could not add to the tempfile: $!");
		return undef;
	}
	return 1;
}

sub commit($)
{
	my ($self) = @_;

	if (!defined($self->{'f'}) || !defined($self->{'tmpfname'}) ||
	    !defined($self->{'fname'})) {
		$self->err("Cannot commit an unopened tempfile");
		return undef;
	}
	$self->debug("RDBG about to commit $self->{tmpfname} to $self->{fname}\n");

	# Fix stuff up
	if (defined($self->{'stat'})) {
		# Mode
		if (!chmod($self->{'stat'}->[2], $self->{'tmpfname'})) {
			$self->err("Could not chmod $self->{stat}->[2] ".
			    $self->{'tmpfname'}.": $!");
			return undef;
		}
		# Owner & group
		if (!chown($self->{'stat'}->[4], $self->{'stat'}->[5],
		    $self->{'tmpfname'})) {
			$self->err("Could not chown $self->{stat}->[4], ".
			    $self->{'stat'}->[5].", $self->{tmpfname}: $!");
			return undef;
		}
	}
	
	if (!rename($self->{'tmpfname'}, $self->{'fname'})) {
		$self->err("Renaming $self->{tmpfname} to $self->{fname}: $!");
		return undef;
	}
	close $self->{'f'};
	$self->debug("RDBG successfully committed $self->{tmpfname} to $self->{fname}\n");
	$self->{'fname'} = $self->{'tmpfname'} = $self->{'f'} = undef;
	return 1;
}

sub rollback($)
{
	my ($self) = @_;

	$self->debug(ref($self)."->rollback() for $self->{fname}\n");
	if (defined($self->{'tmpfname'})) {
		$self->debug("RDBG removing $self->{tmpfname}\n");
		if (!unlink($self->{'tmpfname'})) {
			$self->err("Removing $self->{tmpfname}: $!");
			return undef;
		}
		undef $self->{'tmpname'};
	}
	if (defined($self->{'f'})) {
		$self->debug("RDBG closing the file\n");
		close $self->{'f'};
		undef $self->{'f'};
	}
	undef $self->{'fname'};
	$self->debug("RDBG rollback seems complete\n");
	return 1;
}

sub debug($ $)
{
	my ($self, $msg) = @_;

	if ($self->{'debug'} || $debug) {
		print STDERR $msg;
	}
}

sub do_copy($ $ $)
{
	my ($self, $orig, $f) = @_;
	
	while (<$orig>) {
		print $f $_;
	}
	return 1;
}

END
{
	print STDERR "RDBG File::Append::TempFile END block\n" if $debug;
	print STDERR "RDBG ".keys(%tempfiles)."\n" if $debug;
	foreach (keys %tempfiles) {
		$tempfiles{$_}->rollback() if $tempfiles{$_}->{'tmpfname'};
	}
}

1;