File::Dir::Dumper::Stream::JSON::Reader - reader for stream of JSON objects.

    use File::Dir::Dumper::Stream::JSON::Reader;

    my $reader = File::Dir::Dumper::Stream::JSON::Reader->new(
        {
            input => \*FILEHANDLE,
        }
    );

    while (defined(my $token = $reader->fetch())
    {
        # Do something with $token.
    }

    perldoc File::Dir::Dumper

package File::Dir::Dumper::Stream::JSON::Reader;

use warnings;
use strict;

use base 'File::Dir::Dumper::Base';

use Carp;

use JSON;

__PACKAGE__->mk_accessors(qw(_in));

our $VERSION = '0.0.7';

sub _init
{
    my $self = shift;
    my $args = shift;

    $self->_in($args->{input});

    $self->_init_stream();

    return;
}

sub _readline
{
    my $self = shift;

    return readline($self->_in());
}

sub _eof
{
    my $self = shift;

    return eof($self->_in());
}

sub _init_stream
{
    my $self = shift;

    if ($self->_readline() ne "# JSON Stream by Shlomif - Version 0.2.0\n")
    {
        Carp::confess "No header for JSON stream";
    }

    return;
}

sub fetch
{
    my $self = shift;

    my $buffer = "";
    my $line;

    if ($self->_eof())
    {
        return;
    }

    LINES:
    while (!$self->_eof())
    {
        $line = $self->_readline();
        if ($line eq "--/f\n")
        {
            return from_json($buffer);
        }
        else
        {
            $buffer .= $line;
        }
    }
    Carp::confess "Error! Reached end of file without record terminator.";
}

1; # End of File::Dir::Dumper