File::LocalizeNewlines - Localize the newlines for one or more files

package File::LocalizeNewlines;

use 5.005;
use strict;
use File::Spec       0.80 ();
use File::Find::Rule 0.20 ();
use File::Slurp   9999.04 ();
use Class::Default    1.0 ();
use FileHandle          0 ();
use Params::Util     0.10 '_INSTANCE';

use vars qw{$VERSION @ISA};
BEGIN {
	$VERSION = '1.12';
	@ISA     = 'Class::Default';
}





#####################################################################
# Constructor and Accessors

sub new {
	my $class = ref $_[0] ? ref shift : shift;
	my %args  = @_;

	# Create the basic object
	my $self = bless { }, $class;

	# Check the file filter
	if ( _INSTANCE($args{filter}, 'File::Find::Rule') ) {
		$self->{Find} = $args{filter};
		$self->{Find}->file->relative;
	}

	# Allow for a custom platform
	$self->{newline} = $args{newline} if $args{newline};

	# Check the verbose mode
	if ( _CAN($args{verbose}, 'print') ) {
		$self->{verbose} = $args{verbose};
	} elsif ( $args{verbose} ) {
		$self->{verbose} = 1;
	}

	$self;
}

sub Find {
	my $self = $_[0]->_self;
	$self->{Find} or File::Find::Rule->file->relative;
}

sub newline {
	$_[0]->_self->{newline} or "\n";
}





#####################################################################
# Methods

sub localized {
	my $self      = shift->_self;
	my $file      = (defined $_[0] and ref $_[0]) ? shift
	              : (defined $_[0] and  -f $_[0]) ? shift
	              : return undef;
	my $newline   = $self->newline;
	my $content   = File::Slurp::read_file( $file );

	# Create the localized version of the file
	my $localized = $content;
	$localized =~ s/(?:\015{1,2}\012|\015|\012)/$newline/sg;

	$localized eq $content;
}

sub find {
	my $self = shift->_self;
	my $path = _DIRECTORY(shift) or return ();

	# Find all the files to test
	my @files = $self->Find->in( $path );
	@files = grep {
		! $self->localized(
			File::Spec->catfile( $path, $_ )
			)
		} @files;

	@files;
}

sub localize {
	my $self = shift->_self;
	my $path = (defined $_[0] and ref $_[0]) ? shift
	         : (defined $_[0] and  -e $_[0]) ? shift
	         : return undef;

	# Switch on file or dir
	(-f $path or ref $_[0])
		? $self->_localize_file( $path )
		: $self->_localize_dir( $path );
}

sub _localize_dir {
	my $self = shift->_self;
	my $path = _DIRECTORY(shift) or return undef;

	# Find the files to localise
	my @files = $self->Find->in( $path );

	# Localize the files
	my $count   = 0;
	my $newline = $self->newline;
	foreach ( @files ) {
		my $file      = File::Spec->catfile( $path, $_ );
		my $content   = File::Slurp::read_file( $file );
		my $localized = $content;
		$localized =~ s/(?:\015{1,2}\012|\015|\012)/$newline/sg;
		next if $localized eq $content;
		File::Slurp::write_file( $file, $localized ) or return undef;
		$self->_message( "Localized $file\n" );
		$count++;
	}

	$count;
}

sub _localize_file {
	my $self = shift->_self;
	my $file = (defined $_[0] and ref $_[0]) ? shift
	         : (defined $_[0] and  -f $_[0]) ? shift
	         : return undef;

	# Does the file need to be localised
	my $newline   = $self->newline;
	my $content   = File::Slurp::read_file( $file );
	my $localized = $content;
	$localized =~ s/(?:\015{1,2}\012|\015|\012)/$newline/sg;
	return 0 if $content eq $localized;

	# Save the localised version
	File::Slurp::write_file( $file, $localized ) or return undef;
	$self->_message( "Localized $file\n" ) unless ref $file;

	1;
}

sub _message {
	my $self = shift;
	return 1 unless defined $self->{verbose};
	my $message = shift;
	$message .= "\n" unless $message =~ /\n$/;
	if ( _CAN( $self->{verbose}, 'print' ) ) {
		$self->{verbose}->print( $message );
	} else {
		print STDOUT $message;
	}
}

sub _CAN {
	(_INSTANCE($_[0], 'UNIVERSAL') and $_[0]->can($_[1])) ? shift : undef;
}

sub _DIRECTORY {
	(defined $_[0] and -d $_[0]) ? shift : undef;
}

1;