Forest::Tree::Loader::SimpleUIDLoader - Loads a Forest::Tree heirarchy using UIDs

package Forest::Tree::Loader::SimpleUIDLoader;
use Moose;

our $VERSION   = '0.09';
our $AUTHORITY = 'cpan:STEVAN';

with 'Forest::Tree::Loader';

has 'row_parser' => (
    is      => 'ro',
    isa     => 'CodeRef',
    default => sub {
        sub {
            my $row = shift;
            $row->{node}, $row->{uid}, $row->{parent_uid}
        }
    },
);

sub load {
    my ($self, $table) = @_;

    my $root       = $self->tree;
    my $row_parser = $self->row_parser;

    my %index;

    foreach my $row (@$table) {
        my ($node, $uid, undef) = $row_parser->($row);
        # NOTE: uids MUST be true values ...
        if ($uid) {
            my $t = $self->create_new_subtree(
                node => $node,
                uid  => $uid,
            );
            $index{ $uid } = $t;
        }
    }

    my @orphans;
    foreach my $row (@$table) {
        my (undef, $uid, $parent_uid) = $row_parser->($row);
        # NOTE: uids MUST be true values ...
        if ($uid) {
            my $tree = $index{ $uid };
            if (my $parent = $index{ $parent_uid }) {
                $parent->add_child($tree);
            }
            else {
                push @orphans => $tree;
            }
        }
    }

    if (@orphans) {
        $root->add_children(@orphans);
    }
    else {
        $root->add_child( $index{ (sort keys %index)[0] } );
    }

    $root;
}

__PACKAGE__->meta->make_immutable;

no Moose; 1;

__END__