Form::Factory::Result::Gathered - A group of results

Form-Factory documentation Contained in the Form-Factory distribution.

Index

Code Index:

NAME

Top

Form::Factory::Result::Gathered - A group of results

VERSION

Top

version 0.020

SYNOPSIS

Top

  my $result = Form::Factory::Result::Gathered->new;
  $result->gather_results($other_result1, $other_result2, $other_result3);

  my @child_results = $result->results;

  $result->clear_messages;
  $result->clear_messages_for_field('foo');
  $result->clear_results;
  $result->clear_all;

  my $validated = $result->is_validated;
  my $valid     = $result->is_valid;

  my $has_outcome = $result->is_outcome_known;
  my $success     = $result->is_success;

  my $messages    = $result->messages;
  my $content     = $result->content;

DESCRIPTION

Top

This is a collection of results. The results are grouped and collected together in a way that makes sense to the Form::Factory API.

METHODS

Top

results

  my @results = $self->results;

Returns a list of the results that have been gathered.

gather_results

  $result->gather_results(@results);

Given one or more result objects, it adds them to the list of results already gathered. These are placed in a set such that no result is added more than once. If a result object was already added, it will not be added again.

clear_state

Clears the state of all gathered results. It just calls clear_state recursively on all results.

clear_results

Clears the list of results. results will return an empty list after this is called.

clear_messages

Calls the clear_messages method on all results that have been gathered. This will clear messages for all the associated results.

clear_messages_for_field

  $result->clear_messagesw_for_field($field);

Calls the clear_messages_for_field method on all results that have been gathered.

clear_all

Clears all messages on the gathered results (via clear_message) and then clears all the results (via clear_results).

is_valid

Tests each result for validity. This will return true if every result returns false for is_validated or returns true for is_valid.

is_validated

Returns true if any result returns true for is_validated.

is_success

Tests each result for success. This will return true if every result returns false for is_outcome_known or true for is_success.

is_outcome_known

Returns true if any result returns true for is_outcome_known.

messages

Returns a reference to an array of messages. This includes all messages from the gathered results.

content

Performs a shallow merge of all the return value of each result's content method and returns that.

AUTHOR

Top

Andrew Sterling Hanenkamp <hanenkamp@cpan.org>

COPYRIGHT AND LICENSE

Top

Copyright 2009 Qubling Software LLC.

This library is free software. You can redistribute it and/or modify it under the same terms as Perl itself.

Form-Factory documentation Contained in the Form-Factory distribution. 
package Form::Factory::Result::Gathered;
BEGIN {
  $Form::Factory::Result::Gathered::VERSION = '0.020';
}
use Moose;

use Carp ();
use Scalar::Util qw( blessed refaddr );
use List::MoreUtils qw( all any );

with qw( Form::Factory::Result );


has _results => (
    is       => 'ro',
    isa      => 'HashRef[Form::Factory::Result]',
    required => 1,
    default  => sub { {} },
);


sub results {
    my $self = shift;
    return values %{ $self->_results };
}


sub gather_results {
    my ($self, @results) = @_;

    my $results = $self->_results;
    for my $result (@results) {
        Carp::croak('you attempted to pass a result itself to gather_results(), but you cannot gather results recursively')
            if refaddr $result == refaddr $self;

        my $addr = refaddr $result;
        $results->{$addr} = $result;
    }
}


sub clear_state {
    my $self = shift;
    $_->clear_state for $self->results;
}


sub clear_results {
    my $self = shift;
    %{ $self->_results } = ();
}


sub clear_messages {
    my $self = shift;
    $_->clear_messages for $self->results;
}


sub clear_messages_for_field {
    my $self  = shift;
    my $field = shift;

    $_->clear_messages_for_field($field) for $self->results;
}


sub clear_all {
    my $self = shift;
    $self->clear_state;
    $self->clear_messages;
    $self->clear_results;
}


sub is_valid {
    my $self = shift;
    return all { not $_->is_validated or $_->is_valid } $self->results;
}


sub is_validated {
    my $self = shift;
    return any { $_->is_validated } $self->results;
}


sub is_success {
    my $self = shift;
    return all { not $_->is_outcome_known or $_->is_success } $self->results;
}


sub is_outcome_known {
    my $self = shift;
    return any { $_->is_outcome_known } $self->results;
}


sub messages {
    my $self = shift;
    return [ map { @{ $_->messages } } $self->results ];
}


# Dumb merge
sub content {
    my $self = shift;
    return { map { %{ $_->content } } $self->results };
}


1;