Games::AssaultCube::ServerQuery - Queries a running AssaultCube server for information

	use Games::AssaultCube::ServerQuery;
	my $query = Games::AssaultCube::ServerQuery->new( 'my.server.com' );
	#my $query = Games::AssaultCube::ServerQuery->new( 'my.server.com', 12345 );
	#my $query = Games::AssaultCube::ServerQuery->new({ server => 'foo.com', port => 12345, timeout => 5 });
	my $response = $query->run;
	if ( defined $response ) {
		print "Server is running with " . $response->players . " players\n";
	} else {
		print "Server is not responding!\n";
	}

# Declare our package
package Games::AssaultCube::ServerQuery;

# import the Moose stuff
use Moose;
use MooseX::StrictConstructor;
use Moose::Util::TypeConstraints;

# Initialize our version
use vars qw( $VERSION );
$VERSION = '0.04';

# get some utility stuff
use Games::AssaultCube::Utils qw( default_port tostr get_ac_pingport );
use Games::AssaultCube::ServerQuery::Response;
use IO::Socket::INET;

# TODO make validation so we accept either hostname or IPv4/6...
has 'server' => (
	isa		=> 'Str',
	is		=> 'ro',
	required	=> 1,
);

# <mst> Apocalypse: { my $port_spec = subtype as Int => where { ... }; has 'attr' => (isa => $port_spec, ...); }
{
	my $port_type = subtype as 'Int' => where {
		if ( $_ <= 0 or $_ > 65535 ) {
			return 0;
		} else {
			return 1;
		}
	};

	has 'port' => (
		isa		=> $port_type,
	#	isa		=> 'Int',
		is		=> 'rw',
		default		=> default_port(),
	);
}

has 'timeout' => (
	isa		=> 'Int',
	is		=> 'rw',
	default 	=> 30,
);

has 'get_players' => (
	isa		=> 'Bool',
	is		=> 'rw',
	default		=> 0,
);

sub BUILDARGS {
	my $class = shift;

	if ( @_ == 1 && ! ref $_[0] ) {
		# set the server as the first argument
		return { server => $_[0] };
	} elsif ( @_ == 2 && ! ref $_[0] ) {
		# server/port argument
		return { server => $_[0], port => $_[1] };
	} else {
		# normal hash/hashref way
		return $class->SUPER::BUILDARGS(@_);
	}
}

sub run {
	my $self = shift;

	# Ok, get our socket and send off the PING!
	my $sock = IO::Socket::INET->new(
		Proto		=> 'udp',
		PeerPort	=> get_ac_pingport( $self->port ),
		PeerAddr	=> $self->server,
	) or die "Could not create socket: $!";
	binmode $sock, ":utf8" or die "Unable to set binmode: $!";

	# generate the PING packet
	# TODO support the EXT_XYZ options
	my $pingpacket;
	if ( $self->get_players ) {
		$pingpacket = tostr('1') . tostr('1');
	} else {
		$pingpacket = tostr('1') . tostr('0');
	}

	# send it!
	$sock->send( $pingpacket ) or die "Unable to send: $!";

	# set the alarm, and wait for the response
	my( $datagram, $result );
	eval {
		# perldoc -f alarm says I need to put \n in the die... weird!
		local $SIG{ALRM} = sub { die "alarm\n" };
		alarm $self->timeout;
		$result = $sock->recv( $datagram, 1024 ) or die "Unable to recv: $!";
		alarm 0;
	};
	if ( $@ ) {
		if ( $@ =~ /^alarm/ ) {
			die "Unable to query server: Timed out";
		} else {
			die "Unable to query server: $@";
		}
	} else {
		if ( defined $result and defined $datagram and length( $datagram ) > 0 ) {
			return Games::AssaultCube::ServerQuery::Response->new( $self, $datagram );
		} else {
			return;
		}
	}
}

# from Moose::Manual::BestPractices
no Moose;
__PACKAGE__->meta->make_immutable;

1;
__END__