Geo::Sun - Calculates the Geodetic Position of the Sun over the Surface of the Earth

  use Geo::Sun;
  my $gs=Geo::Sun->new;                              #isa Geo::Sun
  my $point=$gs->set_datetime(DateTime->now)->point; #Full OO interface
  printf "Point isa %s\n", ref($point);              #isa GPS::Point
  printf "Latitude: %s, Longitude: %s\n", $point->latlon;

  use Geo::Sun;
  my $gs=Geo::Sun->new;
  printf "Lat: %s, Lon: %s\n", $gs->point->latlon;

  my $gs=Geo::Sun->new;

  my $point=$gs->point;
  my $point=$gs->set_datetime(DateTime->now)->point;

  my $point=$gs->point_dt($datetime);

  my $point=$gs->set_datetime($datetime)->point;

  my $sun=$gs->sun;

  my $ellipsoid=$gs->ellipsoid;  #WGS84

    Michael R. Davis
    CPAN ID: MRDVT
    STOP, LLC
    domain=>stopllc,tld=>com,account=>mdavis
    http://www.stopllc.com/

	The BSD License

package Geo::Sun;
use strict;
use warnings;
use Astro::Coord::ECI::Sun;
use DateTime;
use Geo::Constants qw{PI};
use Geo::Functions qw{deg_rad};
use Geo::Ellipsoids;
use GPS::Point;

BEGIN {
    use vars qw($VERSION);
    $VERSION     = '0.04';
}

sub new {
  my $this = shift();
  my $class = ref($this) || $this;
  my $self = {};
  bless $self, $class;
  $self->initialize(@_);
  return $self;
}

sub initialize {
  my $self=shift;
  %$self=@_;
  $self->sun(Astro::Coord::ECI::Sun->new)
    unless ref($self->sun) eq "Astro::Coord::ECI::Sun";
  $self->ellipsoid(Geo::Ellipsoids->new)
    unless ref($self->ellipsoid) eq "Geo::Ellipsoids";
  if (defined $self->datetime) {
    $self->point_recalculate; #supports $gs->new(datetime=>$dt)
  } else {
    $self->datetime(DateTime->now)
  }
  $self->initialize2; #a hook if you need it
  return $self;
}

sub initialize2 {
  my $self=shift;
  return $self;
}

sub point {
  my $self=shift;
  return $self->{'point'};
}

sub point_dt {
  my $self=shift;
  return $self->set_datetime(@_)->point;
}

sub datetime {
  my $self = shift;
  if (@_) {
    $self->{"datetime"}=shift;
    $self->point_recalculate;
  }
  return $self->{"datetime"};
}

sub set_datetime {
  my $self=shift;
  $self->datetime(@_) if @_;
  return $self;
}

sub point_recalculate {
  my $self=shift;
  my $epoch=$self->datetime->clone->set_time_zone("UTC")->epoch;
  my ($psi, $lambda, $h) = $self->sun->universal($epoch)->geodetic;
  #speed is 2 pi distance from the polar axis to the surface
  #of the earth at latitude divided by 1 day (m/s)
  my $speed=2 * PI() * $self->ellipsoid->n_rad($psi) * cos($psi) / 24 / 60 / 60;
  $self->{'point'}=GPS::Point->new(
    time        => $self->sun->universal, #float seconds unix epoch (UTC)
    lat         => deg_rad($psi),         #signed decimal degrees
    lon         => deg_rad($lambda),      #signed decimal degrees
    alt         => $h * 1000,             #meters above the WGS-84 ellipsoid
    speed       => $speed, #is this right #meters/second (over ground)
    heading     => 270,  #need real value #degrees clockwise from North
    mode        => 3,                     #GPS mode 3-D
    tag         => "Geo::Sun",            #Name of the GPS message for data
  ); 
  $self->point_onchange; #a hook if you need it.
  return $self;
}

sub point_onchange {
  my $self=shift;
  return $self;
}

sub sun {
  my $self=shift;
  $self->{'sun'}=shift if @_;
  return $self->{'sun'};
}

sub ellipsoid {
  my $self = shift();
  $self->{'ellipsoid'}=shift if (@_);
  return $self->{'ellipsoid'};
}

1;